blob: c554f20831c99dd3c5b0f657826ebf30dd906975 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
pkgname=sdl2
pkgver=2.0.0
pkgrel=4
pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 2)"
arch=('i686' 'x86_64')
url="http://www.libsdl.org"
license=('MIT')
depends=('glibc' 'libxext' 'libxrender' 'libx11' 'libgl')
makedepends=('alsa-lib' 'mesa' 'libpulse' 'cmake' 'libxrandr' 'libxinerama')
optdepends=('alsa-lib: ALSA audio driver'
'libpulse: PulseAudio audio driver')
source=("http://www.libsdl.org/release/SDL2-${pkgver}.tar.gz")
md5sums=('beec89afb6edcc6f0abc4114f2e6bcf7')
build() {
cd "${srcdir}/SDL2-${pkgver}"
mkdir build && cd build
cmake .. \
-DCMAKE_INSTALL_PREFIX=/usr \
-DSDL_STATIC=OFF \
-DRPATH=OFF
make
}
package() {
cd "${srcdir}/SDL2-${pkgver}/build"
make DESTDIR="${pkgdir}/" install
install -Dm644 ../COPYING.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
