blob: 0e759b8ad3f1d9b2b2627c3e96f9815e25e0647e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# $Id: PKGBUILD 216432 2014-07-03 20:25:44Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
# Contributor: riai <riai@bigfoot.com>, Ben <ben@benmazer.net>
pkgbase=sip
pkgname=('sip' 'python-sip' 'python2-sip')
pkgver=4.16.2
pkgrel=1
arch=('i686' 'x86_64')
url='http://www.riverbankcomputing.com/software/sip/intro'
license=('custom:"sip"')
makedepends=('python' 'python2')
source=("http://downloads.sourceforge.net/pyqt/${pkgbase}-${pkgver}.tar.gz")
md5sums=('1ca96f90a7496a3c9664fdaa76205719')
build() {
cp -r ${pkgbase}-${pkgver} python2-${pkgbase}-${pkgver}
cd ${pkgbase}-${pkgver}
python configure.py CFLAGS="${CFLAGS}" LFLAGS="${LDFLAGS}"
make
### Python2 version ###
cd ../python2-${pkgbase}-${pkgver}
python2 configure.py CFLAGS="${CFLAGS}" LFLAGS="${LDFLAGS}"
make
}
package_sip() {
pkgdesc="A tool that makes it easy to create Python bindings for C and C++ libraries"
depends=('glibc')
cd ${pkgbase}-${pkgver}
make DESTDIR="${pkgdir}" install -C sipgen
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
package_python-sip() {
pkgdesc="Python 3.x SIP bindings for C and C++ libraries"
depends=('sip' 'python')
cd ${pkgbase}-${pkgver}
make DESTDIR="${pkgdir}" install -C siplib
install -Dm644 sipconfig.py "${pkgdir}"/usr/lib/python3.4/site-packages/sipconfig.py
install -Dm644 sipdistutils.py "${pkgdir}"/usr/lib/python3.4/site-packages/sipdistutils.py
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
package_python2-sip() {
pkgdesc="Python 2.x SIP bindings for C and C++ libraries"
depends=('sip' 'python2')
cd python2-${pkgbase}-${pkgver}
make DESTDIR="${pkgdir}" install -C siplib
install -Dm644 sipconfig.py "${pkgdir}"/usr/lib/python2.7/site-packages/sipconfig.py
install -Dm644 sipdistutils.py "${pkgdir}"/usr/lib/python2.7/site-packages/sipdistutils.py
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
