blob: 8290fdac8d2dc747f9da249389f03c3ab37d7cc6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# $Id: PKGBUILD 73980 2012-07-18 00:34:26Z speps $
# Maintainer: Ray Rashif <schiv@archlinux.org>
# Contributor: speps <speps at aur dot archlinux dot org>
pkgname=suil
pkgver=0.6.16
pkgrel=1
pkgdesc="A lightweight C library for loading and wrapping LV2 plugin UIs"
arch=('i686' 'x86_64')
url="http://drobilla.net/software/suil/"
license=('custom:ISC')
depends=('lv2>=1.6.0')
makedepends=('python2' 'qt4' 'gtk2')
optdepends=('qt4: Qt 4.x UI wrapping support'
'gtk2: GTK+ 2.x UI wrapping support')
source=("http://download.drobilla.net/$pkgname-$pkgver.tar.bz2")
md5sums=('644ccd95179f32f01cee0107a1ad88c9')
build() {
cd "$srcdir/$pkgname-$pkgver"
# remove ldconfig --speps
sed -i "/ldconfig/d" wscript
python2 waf configure --prefix=/usr
python2 waf build $MAKEFLAGS
}
package() {
cd "$srcdir/$pkgname-$pkgver"
python2 waf install --destdir="$pkgdir"
# license
install -Dm644 COPYING \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set ts=2 sw=2 et:
|
