extra/telepathy-kde-desktop-applets/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# $Id: PKGBUILD 211771 2014-04-26 07:07:14Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>

pkgname=telepathy-kde-desktop-applets
_pkgname=ktp-desktop-applets
pkgver=0.8.1
pkgrel=1
pkgdesc="The KDE-Telepathy Plasma desktop applets"
arch=('i686' 'x86_64')
url="http://community.kde.org/Real-Time_Communication_and_Collaboration"
license=('GPL')
depends=('telepathy-kde-common-internals' 'kdebase-workspace')
makedepends=('cmake' 'automoc4')
groups=('kde-telepathy')
conflicts=('telepathy-kde-contact-applet' 'telepathy-kde-presence-applet')
replaces=('telepathy-kde-contact-applet' 'telepathy-kde-presence-applet')
source=("http://download.kde.org/stable/kde-telepathy/${pkgver}/src/${_pkgname}-${pkgver}.tar.bz2")
sha1sums=('6721198e066f70a8ef3ce3f08e8cbfed5f61493b')

prepare() {
  mkdir build
}

build() {
  cd build
  cmake ../${_pkgname}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}