blob: c773a5fcebccec38c9c3f1c8bcb6a3378b1f3687 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# $Id: PKGBUILD 120780 2011-04-26 15:03:27Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=tomboy
pkgver=1.6.1
pkgrel=1
pkgdesc="Desktop note-taking application for Linux and Unix"
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.gnome.org/projects/tomboy/"
depends=('gtk2' 'gtkspell' 'ndesk-dbus-glib' 'mono-addins' 'gnome-sharp')
makedepends=('intltool' 'pkgconfig' 'gnome-doc-utils')
options=('!libtool' '!emptydirs' '!makeflags')
groups=('gnome-extra')
install=tomboy.install
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/1.6/${pkgname}-${pkgver}.tar.bz2)
sha256sums=('4c0b5e0103682711e1cd620c9c617716a33b3520d62c22a2f6ab7bab2a54e61c')
build() {
export MONO_SHARED_DIR="${srcdir}/.wabi"
mkdir -p "${MONO_SHARED_DIR}"
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-scrollkeeper \
--disable-update-mimedb
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 install
install -m755 -d "${pkgdir}/usr/share/gconf/schemas"
gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" --domain tomboy ${pkgdir}/etc/gconf/schemas/*.schemas
rm -f ${pkgdir}/etc/gconf/schemas/*.schemas
}
|
