blob: 0a8c7df14cfcf76179374bcf67a4c54bafe52cf5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# $Id: PKGBUILD 198462 2013-10-30 15:01:19Z allan $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgbase=totem
pkgname=('totem' 'totem-plugin')
pkgver=3.10.1
pkgrel=1
pkgdesc="GNOME3 movie player based on GStreamer"
url="http://www.gnome.org"
arch=(i686 x86_64)
license=(GPL2 custom)
depends=(gst-plugins-base gst-plugins-good totem-plparser desktop-file-utils iso-codes libpeas
hicolor-icon-theme gnome-icon-theme gsettings-desktop-schemas dconf clutter-gst
clutter-gtk python-gobject python-xdg gst-plugins-bad)
makedepends=(intltool libnautilus-extension lirc-utils vala grilo dbus-glib zeitgeist
itstool docbook-xsl python-pylint)
options=('!emptydirs')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgbase/${pkgver%.*}/$pkgbase-$pkgver.tar.xz
browser-plugins.ini bugreport.patch)
sha256sums=('b6b6038c9104965671a6d25e98496a487c3a9c590c9c104f668bd9f4fa7be9e2'
'a50a3bbf35f0535f7e8e20af1893446a2e5711015484f9ae6d1ff91af3b23c4e'
'30481dab7e21b66257e3238f5a8b708e1a5c4797d7da904f7ebaba4c2c2ef167')
prepare() {
cd "$pkgbase-$pkgver"
# Make compatible with Python 3 and Gstreamer 1.0
patch -Np1 -i ../bugreport.patch
}
build() {
cd "$pkgbase-$pkgver"
./configure --prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/totem \
--localstatedir=/var \
--disable-static \
--enable-python \
--enable-nautilus
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package_totem() {
groups=(gnome)
install=totem.install
optdepends=('gst-plugins-ugly: Extra media codecs'
'gst-libav: Extra media codecs'
'lirc-utils: Infrared Remote Control plugin'
'grilo-plugins: Browse sidebar (remote media)'
'zeitgeist: Zeitgeist plugin')
cd "$pkgbase-$pkgver"
make DESTDIR="${pkgdir}" install
rm -r "$pkgdir/usr/lib/mozilla"
rm "$pkgdir/usr/lib/totem/totem-plugin-viewer"
install -Dm644 COPYING "$pkgdir/usr/share/licenses/totem/COPYING"
}
package_totem-plugin() {
groups=(gnome)
pkgdesc="Totem plugin for web browsers"
depends=("totem=$pkgver" dbus-glib)
backup=(etc/totem/browser-plugins.ini)
cd "$pkgbase-$pkgver"
make -C browser-plugin \
plugindir=/usr/lib/mozilla/plugins \
xptdir=/usr/lib/mozilla/plugins \
DESTDIR="$pkgdir" install
install -Dm644 ../browser-plugins.ini "$pkgdir/etc/totem/browser-plugins.ini"
install -Dm644 COPYING "$pkgdir/usr/share/licenses/totem-plugin/COPYING"
}
|
