blob: ed89d82b6c90f0d574b2b6f2eb610e824068796b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# $Id: PKGBUILD 120757 2011-04-26 11:04:01Z heftig $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgbase=totem
pkgname=('totem' 'totem-plugin')
pkgver=3.0.1
pkgrel=1
url="http://www.hadess.net/totem.php3"
arch=('i686' 'x86_64')
license=('GPL2' 'custom')
makedepends=('intltool' 'gnome-doc-utils' 'gstreamer0.10-base-plugins' 'gstreamer0.10-good-plugins' 'totem-plparser'
'libpeas' 'pygobject' 'pygobject-devel' 'nautilus' 'libxxf86vm' 'libxtst' 'desktop-file-utils' 'iso-codes' 'libgdata'
'xulrunner' 'lirc-utils' 'libepc' 'bluez' 'vala')
options=('!libtool' '!emptydirs')
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgbase}/${pkgver%.*}/${pkgbase}-${pkgver}.tar.bz2)
sha256sums=('013b6cfedac6ff264aa27de7346597d0b8da7f4ed1f91b2c966a13d3fdff679a')
build() {
cd "${srcdir}/${pkgbase}-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc \
--libexecdir=/usr/lib/totem \
--localstatedir=/var --disable-static \
--enable-python --enable-nautilus \
--with-dbus --disable-scrollkeeper
make
}
package_totem() {
pkgdesc="A GNOME3 integrated movie player based on Gstreamer."
depends=('gstreamer0.10-base-plugins' 'gstreamer0.10-good-plugins' 'totem-plparser' 'libxxf86vm' 'libxtst' 'desktop-file-utils' 'iso-codes' 'python2' 'libpeas' 'hicolor-icon-theme' 'gnome-icon-theme-symbolic' 'gsettings-desktop-schemas')
groups=('gnome-extra')
install=totem.install
optdepends=('gstreamer0.10-ugly-plugins: Extra media codecs'
'gstreamer0.10-bad-plugins: Extra media codecs'
'gstreamer0.10-ffmpeg: Extra media codecs'
'lirc-utils: Infrared Remote Control plugin'
'libepc: Publish Playlist plugin'
'libgdata: YouTube Browser plugin'
'bluez: Bemused plugin')
cd "${srcdir}/${pkgbase}-${pkgver}"
make DESTDIR="${pkgdir}" install
rm -rf "${pkgdir}/usr/lib/mozilla"
rm -f "${pkgdir}/usr/lib/totem/totem-plugin-viewer"
sed -i "s|#!/usr/bin/python$|#!/usr/bin/python2|" \
$pkgdir/usr/lib/totem/{totem/totem-bugreport.py,plugins/iplayer/iplayer2.py}
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/totem/COPYING"
}
package_totem-plugin() {
pkgdesc="Totem mozilla/firefox plugin"
depends=("totem=${pkgver}")
cd "${srcdir}/${pkgbase}-${pkgver}"
make -C browser-plugin \
plugindir=/usr/lib/mozilla/plugins \
xptdir=/usr/lib/mozilla/plugins \
DESTDIR="${pkgdir}" install
rm -rf "${pkgdir}/usr/share"
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/totem-plugin/COPYING"
}
|
