blob: 03dbb40dded1a8dc2dd0489527d0c6d76ad45a17 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# $Id: PKGBUILD 206043 2014-02-16 10:13:00Z jgc $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgname=udisks2
pkgver=2.1.2
pkgrel=1
pkgdesc="Disk Management Service, version 2"
arch=('i686' 'x86_64')
url="http://www.freedesktop.org/wiki/Software/udisks"
license=('GPL2')
depends=('glib2' 'systemd' 'polkit' 'libatasmart' 'util-linux')
makedepends=('intltool' 'docbook-xsl' 'gobject-introspection' 'python')
optdepends=('parted: partition management'
'gptfdisk: GUID partition table support'
'ntfs-3g: NTFS filesystem management support'
'dosfstools: VFAT filesystem management support')
source=(http://udisks.freedesktop.org/releases/udisks-$pkgver.tar.bz2{,.sign}
git-fixes.patch)
sha256sums=('afe928fe7f44086b835257efc3fcbe503e2da7c988a773c997d0291bbab4a637'
'SKIP'
'52a9b9f039f9f115414715375f2b5874b79b5b67fbe2bdf3105b46d3a35f673f')
prepare() {
cd udisks-$pkgver
patch -Np1 -i ../git-fixes.patch
}
build() {
cd udisks-$pkgver
./configure --prefix=/usr --sysconfdir=/etc \
--sbindir=/usr/bin \
--with-systemdsystemunitdir=/usr/lib/systemd/system \
--localstatedir=/var --disable-static
make
}
package() {
cd udisks-$pkgver
make DESTDIR="$pkgdir" install \
bash_completiondir=/usr/share/bash-completion/completions
}
|
