blob: 684b71ef1ffeca585293f7ebc6f373530d837511 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id: PKGBUILD 216918 2014-07-15 19:44:25Z dreisner $
# Maintainer: Dave Reisner <dreisner@archlinux.org>
# Contributor: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Douglas Soares de Andrade
# Contributor: Roberto Alsina <ralsina@kde.org>
pkgname=varnish
pkgver=4.0.1
pkgrel=1
pkgdesc="High-performance HTTP accelerator"
arch=('i686' 'x86_64')
url="http://www.varnish-cache.org/"
license=('BSD')
depends=('gcc' 'libedit' 'pcre')
makedepends=('python-docutils')
optdepends=('python: needed for vmod development')
backup=('etc/varnish/default.vcl')
install=$pkgname.install
source=("http://repo.varnish-cache.org/source/$pkgname-$pkgver.tar.gz"
varnish-vcl-reload
varnish.service)
md5sums=('53e272f448b2109ab370e03d794a243f'
'03196dee7fc68e75069393d52c370762'
'699d118a069c2e63e49c81f275ce2658')
build() {
cd "$pkgname-$pkgver"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var/lib \
--sbindir=/usr/bin
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -m755 "$srcdir/varnish-vcl-reload" "$pkgdir/usr/bin"
install -Dm644 "$srcdir/$pkgname.service" "$pkgdir/usr/lib/systemd/system/$pkgname.service"
# config
install -Dm644 "etc/example.vcl" "$pkgdir/etc/varnish/default.vcl"
install -Dm644 "etc/builtin.vcl" "$pkgdir/usr/share/doc/varnish/builtin.vcl"
# license
install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|
