blob: 89e9a668ed3ec9cb5750f5b86dc55ecec9d1e299 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# $Id: PKGBUILD 165295 2012-08-15 00:30:47Z dreisner $
# Maintainer: Dave Reisner <dreisner@archlinux.org>
# Contributor: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Douglas Soares de Andrade
# Contributor: Roberto Alsina <ralsina@kde.org>
pkgname=varnish
pkgver=3.0.2
pkgrel=6
pkgdesc="High-performance HTTP accelerator"
arch=('i686' 'x86_64')
url="http://www.varnish-cache.org/"
license=('BSD')
depends=('gcc' 'libedit' 'pcre')
backup=('etc/conf.d/varnish'
'etc/varnish/default.vcl')
install=$pkgname.install
options=('!libtool')
source=("http://repo.varnish-cache.org/source/$pkgname-$pkgver.tar.gz"
"$pkgname.conf.d"
"rc.$pkgname"
varnish-vcl-reload
varnish.service)
md5sums=('c8eae0aabbe66b6daabdf3a1f58cd47a'
'edd1237d097d72173d9772754335890c'
'40b4c83b3ad225ed2f4bd7e677fe41a2'
'56be884f43b8b4c900a073d9282f124a'
'45cc1fd57aa2ffc22d6af62f9eedc842')
build() {
cd "$pkgname-$pkgver"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var/lib
make
}
package() {
make -C "$pkgname-$pkgver" DESTDIR="$pkgdir" install
# reload helper
install -m755 "$srcdir/varnish-vcl-reload" "$pkgdir/usr/bin"
# sysvinit
install -Dm755 "$srcdir/rc.$pkgname" "$pkgdir/etc/rc.d/$pkgname"
install -Dm644 "$srcdir/$pkgname.conf.d" "$pkgdir/etc/conf.d/$pkgname"
# systemd
install -Dm644 "$srcdir/$pkgname.service" "$pkgdir/usr/lib/systemd/system/$pkgname.service"
# license
install -Dm644 "$pkgname-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|
