blob: 376ecb7596f02ee16564ada8093f42a14f590d95 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# $Id: PKGBUILD 215170 2014-06-14 19:17:24Z andyrtr $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
pkgname=vice
pkgver=2.4
pkgrel=6
pkgdesc="The Versatile Commodore 8-bit Emulator"
arch=('i686' 'x86_64')
license=('GPL')
url="http://vice-emu.sourceforge.net/"
depends=('alsa-lib' 'giflib' 'libxxf86vm' 'vte' 'libnet' 'libpcap')
makedepends=('xorg-font-utils')
options=('!makeflags')
install=vice.install
source=("http://downloads.sourceforge.net/project/vice-emu/releases/${pkgname}-${pkgver}.tar.gz"
'vice-2.4-x11video.patch'
'vice-2.4-no-fc-cache-no-lib64.patch'
'vice-2.4-notexi-notxt.patch'
'vice-2.4-zlib-1.2.7.patch'
'vice-2.4-giflib-5.1.0.patch')
md5sums=('b017647a0c159bbe43cdb81762d1c577'
'99931efcb779734c9df069e94f0b38a5'
'b0d1392664decd3169740baf90661710'
'877f93db1550ea81386aae7c3b578442'
'9d9f62f05a967a5926df496e86404148'
'94563e3023d804341f1d252c0e6d1384')
prepare() {
cd ${pkgname}-${pkgver}
patch -Np1 -i "${srcdir}/vice-2.4-x11video.patch"
patch -Np1 -i "${srcdir}/vice-2.4-no-fc-cache-no-lib64.patch"
patch -Np1 -i "${srcdir}/vice-2.4-notexi-notxt.patch"
patch -Np1 -i "${srcdir}/vice-2.4-zlib-1.2.7.patch"
patch -Np1 -i "${srcdir}/vice-2.4-giflib-5.1.0.patch"
sed -i 's/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/' configure.in
autoreconf -vi
}
build() {
cd ${pkgname}-${pkgver}
./configure --prefix=/usr \
--enable-ethernet \
--with-alsa \
--enable-fullscreen \
--enable-gnomeui \
--disable-ffmpeg
make
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" realdocdir="/usr/share/doc/vice" install
ln -s /usr/share/doc/vice "${pkgdir}/usr/lib/vice/doc"
}
|
