blob: e54d2ecb6bde5b81bcbfc482be18cfbbbfb749f8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# $Id: PKGBUILD 125719 2011-05-28 14:45:23Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Sarah Hay <sarahhay@mb.sympatico.ca>
# Contributor: Martin Sandsmark <martin.sandsmark@kde.org>
pkgname=vlc
pkgver=1.1.9
pkgrel=3
pkgdesc="A multi-platform MPEG, VCD/DVD, and DivX player"
arch=('i686' 'x86_64')
url="http://www.videolan.org/vlc/"
license=('GPL')
depends=('a52dec' 'fluidsynth' 'libmtp' 'libdvbpsi' 'libcdio'
'libdca' 'qt' 'libproxy' 'sdl_image' 'libdvdnav' 'mesa'
'lua' 'v4l-utils' 'libcddb' 'smbclient' 'libmatroska' 'zvbi'
'taglib' 'sysfsutils' 'libmpcdec' 'ffmpeg' 'faad2'
'libshout' 'libmad' 'fribidi' 'libmpeg2' 'libmodplug'
'ttf-freefont' 'libxv' 'libass' 'xdg-utils' 'desktop-file-utils')
makedepends=('avahi' 'pkgconfig' 'libxpm' 'live-media' 'libnotify'
'flac' 'libtheora' 'alsa-lib' 'jack' 'kdelibs' 'udev'
'libraw1394' 'libdc1394' 'libavc1394' 'libva' 'libpulse'
'lirc-utils' 'gnutls' 'libcaca')
optdepends=('avahi: for service discovery using bonjour protocol'
'libnotify: for notification plugin'
'ncurses: for ncurses interface support'
'libdvdcss: for decoding encrypted DVDs'
'lirc-utils: for lirc plugin'
'libavc1394: for devices using the 1394ta AV/C'
'libdc1394: for IEEE 1394 plugin'
'kdelibs: KDE Solid hardware integration'
'vdpau-video: VDPAU backend for VA API (for GPU acceleration on Nvidia cards)'
'libpulse: PulseAudio support')
conflicts=('vlc-plugin')
replaces=('vlc-plugin')
options=('!libtool')
install=vlc.install
source=("http://download.videolan.org/pub/videolan/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.bz2")
md5sums=('06adb1848e6b87fbe1ced77ec0f91e4c')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i -e 's:truetype/freefont:TTF:g' modules/misc/freetype.c
./configure --prefix=/usr \
--disable-rpath \
--enable-faad \
--enable-v4l \
--enable-snapshot \
--enable-dbus-control \
--enable-nls \
--enable-lirc \
--enable-pvr \
--enable-ncurses \
--with-live555-tree=/usr/lib/live \
--enable-realrtsp
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}/" install
for res in 16 32 48 128; do
install -D -m644 "${srcdir}/vlc-${pkgver}/share/icons/${res}x${res}/vlc.png" \
"${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/vlc.png"
done
}
|
