summaryrefslogtreecommitdiff
path: root/extra/xorg-font-util/PKGBUILD
blob: 5dd73707cc8c078e6cf163e00eaddc2a0c646115 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
# $Id: PKGBUILD 149063 2012-02-05 16:06:39Z bisson $
# Contributor: Jan de Groot <jgc@archlinux.org>
# Maintainer: Gaetan Bisson <bisson@archlinux.org>

pkgname=xorg-font-util
pkgver=1.2.0
pkgrel=2
pkgdesc='X.Org font utilities'
url='http://xorg.freedesktop.org/'
arch=('i686' 'x86_64')
license=('custom')
makedepends=('xorg-util-macros')
source=("${url}/releases/individual/font/font-util-${pkgver}.tar.bz2")
sha1sums=('011fa9c8fe08d9f6f848df570374ed1cb7488146')

replaces=('font-util')
provides=('font-util')
conflicts=('font-util')
groups=('xorg-fonts' 'xorg')

build() {
	cd "${srcdir}/font-util-${pkgver}"

	./configure \
		--prefix=/usr \
		--mandir=/usr/share/man \
		--with-mapdir=/usr/share/fonts/util \
		--with-fontrootdir=/usr/share/fonts \

	make
}

package() {
	cd "${srcdir}/font-util-${pkgver}"
	make DESTDIR="${pkgdir}" install
	install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}