blob: b559dd258eb36481620ac6e14acb55eb10b4f44a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 123881 2011-05-14 00:52:40Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=xscreensaver
pkgver=5.13
pkgrel=1
pkgdesc="Screen saver and locker for the X Window System"
arch=('i686' 'x86_64')
url="http://www.jwz.org/xscreensaver/"
license=('BSD')
depends=('libxxf86vm' 'libglade' 'mesa' 'pam' 'xorg-appres' 'libxmu')
makedepends=('bc')
backup=('etc/pam.d/xscreensaver')
source=(http://www.jwz.org/xscreensaver/${pkgname}-${pkgver}.tar.gz \
add-electricsheep.diff xscreensaver.pam LICENSE)
md5sums=('a1a55b763e17c5c83a2b7cb5ddf23560'
'f82524626ed8a6832cd279e0548a9b46'
'367a3538f54db71f108b34cfa31088ac'
'5e7f3f2a63d20a484742f5b4cb5d572c')
sha1sums=('3bdac6122e5b7b0cffcc90b3b75dc7fa001c0181'
'65c2933380267475f2c4560bc22f4350393b00ce'
'106635aa1aae51d6f0668b1853f6c49a4fe9d3d8'
'4209ea586b204fd1d81c382a0522c654f9fd9134')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -Np0 -i "${srcdir}/add-electricsheep.diff"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib --with-x-app-defaults=/usr/share/X11/app-defaults \
--with-pam --without-motif --with-gtk --with-gl \
--without-gle --with-xpm --with-pixbuf --with-jpeg
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make install_prefix="${pkgdir}" install
install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -D -m644 ../xscreensaver.pam "${pkgdir}/etc/pam.d/xscreensaver"
chmod 755 "${pkgdir}/usr/bin/xscreensaver"
echo "NotShowIn=KDE;GNOME;" >> "${pkgdir}/usr/share/applications/xscreensaver-properties.desktop"
}
|
