blob: f5da6633b67f205a6761bb2d6632b8658be0739b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 169475 2012-10-21 21:14:01Z eric $
# Maintainer:
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: György Balló <ballogy@freestart.hu>
pkgname=zeitgeist
pkgver=0.9.5
pkgrel=1
pkgdesc="A service which logs the users's activities and events and makes relevant information available to other applications"
arch=('i686' 'x86_64')
url="http://zeitgeist-project.com/"
license=('GPL')
depends=('python2-dbus' 'python2-gobject2' 'python2-xdg' 'xapian-core')
makedepends=('intltool' 'raptor' 'python2-rdflib')
checkdepends=('vala')
source=("https://launchpad.net/$pkgname/${pkgver%.*}/$pkgver/+download/$pkgname-$pkgver.tar.bz2")
md5sums=('5841e4624b07ba74866fb177f1c9aae7')
build() {
cd "$srcdir/$pkgname-$pkgver"
sed -i 's/python -/$PYTHON -/' configure
PYTHON=/usr/bin/python2 LIBS+="-lgmodule-2.0" ./configure --prefix=/usr \
--sysconfdir=/etc --libexecdir=/usr/lib/zeitgeist --localstatedir=/var
make
}
check() {
cd "$srcdir/$pkgname-$pkgver"
make -j1 check
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" zeitgeistdocdir=/usr/share/doc/zeitgeist install
install -D -m644 data/zeitgeist-daemon.bash_completion "$pkgdir/usr/share/bash-completion/completions/zeitgeist-daemon"
}
|
