blob: 5b6368bc4a777fdb218be069c668243e8d928062 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 152906 2012-03-10 16:25:37Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=gnome-panel
pkgver=3.3.91
pkgrel=1
arch=('i686' 'x86_64')
license=('GPL')
pkgdesc="The GNOME Panel"
url="http://www.gnome.org"
depends=('gnome-menus' 'gnome-desktop' 'evolution-data-server' 'librsvg' 'libwnck3' 'libsm' 'dconf' 'telepathy-glib')
makedepends=('gnome-doc-utils' 'intltool' 'gobject-introspection' 'networkmanager' 'libcanberra')
install=gnome-panel.install
groups=('gnome')
options=('!libtool' '!emptydirs')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
sha256sums=('6ec1341e37b830d3bd91feb3b4b144c29b72923608e7d188ee9db1ea8eb7717b')
build() {
cd "$pkgname-$pkgver"
PYTHON=/usr/bin/python2 ./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-static \
--libexecdir=/usr/lib/gnome-panel \
--disable-scrollkeeper \
--disable-schemas-compile
make
}
package() {
cd "$pkgname-$pkgver"
make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="$pkgdir" install
install -m755 -d "$pkgdir/usr/share/gconf/schemas"
gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/$pkgname.schemas" --domain gnome-panel-3.0 "$pkgdir"/etc/gconf/schemas/*.schemas
rm -f "$pkgdir"/etc/gconf/schemas/*.schemas
}
|
