blob: 7f30824784cc8b8eb213b0dc4b72ce64b3e715fa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id: PKGBUILD 138222 2011-09-19 09:47:58Z heftig $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgbase=gtkmm3
_pkgbasename=gtkmm
pkgname=('gtkmm3' 'gtkmm3-docs')
pkgver=3.1.90.1
pkgrel=1
arch=('i686' 'x86_64')
makedepends=('gtk3' 'pangomm' 'atkmm' 'glibmm-docs' 'mm-common')
license=('LGPL')
options=('!libtool' '!emptydirs')
url="http://gtkmm.sourceforge.net/"
source=(http://ftp.gnome.org/pub/GNOME/sources/${_pkgbasename}/3.1/${_pkgbasename}-${pkgver}.tar.xz)
sha256sums=('f620f2c4e9d4037a5b9e42f0dbeef33d9c461c30226767e134087f92bb0567bc')
build() {
cd "${srcdir}/${_pkgbasename}-${pkgver}"
./configure --prefix=/usr
make
}
package_gtkmm3() {
pkgdesc="C++ bindings for gtk3"
depends=('gtk3' 'pangomm' 'atkmm')
cd "${srcdir}/${_pkgbasename}-${pkgver}"
sed -i -e 's/^doc_subdirs/#doc_subdirs/' Makefile
make DESTDIR="${pkgdir}" install
}
package_gtkmm3-docs() {
pkgdesc="Developer documentation for gtkmm v3"
cd "${srcdir}/${_pkgbasename}-${pkgver}"
make -C docs DESTDIR="${pkgdir}" install
}
|
