blob: 9f418eaed2233b74d6939fe35c9b50019aea632b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# $Id: PKGBUILD 162556 2012-06-27 12:58:08Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
pkgbase=kdebindings-python
pkgname=('kdebindings-python'
'kdebindings-python2')
pkgver=4.8.95
pkgrel=1
url='https://projects.kde.org/projects/kde/kdebindings/pykde4'
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
groups=('kdebindings')
makedepends=('cmake' 'automoc4' 'boost' 'kdepim-runtime' 'python2-pyqt' 'qscintilla')
source=("http://download.kde.org/unstable/${pkgver}/src/pykde4-${pkgver}.tar.xz")
sha1sums=('e0b674d266f679d9dc36b28bff46767cba97f280')
build() {
export PYTHONDONTWRITEBYTECODE="TRUE"
cd "${srcdir}"
mkdir build
cd build
cmake ../pykde4-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DPYTHON_LIBRARY=/usr/lib/libpython3.2mu.so.1.0
make
cd ..
mkdir build-python2
cd build-python2
cmake ../pykde4-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DPYTHON_EXECUTABLE=/usr/bin/python2
make
}
package_kdebindings-python() {
pkgdesc="A set of Python 3.x bindings for KDE"
depends=('kdepim-runtime' 'pyqt' 'qscintilla')
cd "${srcdir}"/build
make DESTDIR="${pkgdir}" install
}
package_kdebindings-python2() {
pkgdesc="A set of Python 2.x bindings for KDE"
depends=('kdepim-runtime' 'python2-pyqt' 'qscintilla')
conflicts=('kdebindings-python<4.8.1-2')
cd "${srcdir}"/build-python2
make DESTDIR="${pkgdir}" install
# Fix conflicts
rm "${pkgdir}"/usr/bin/pykdeuic4
ln -sf /usr/lib/python2.7/site-packages/PyQt4/uic/pykdeuic4.py \
"${pkgdir}"/usr/bin/python2-pykdeuic4
mv "${pkgdir}"/usr/share/apps/pykde4/examples \
"${pkgdir}"/usr/share/apps/pykde4/python2-examples
mv "${pkgdir}"/usr/share/sip/PyKDE4 \
"${pkgdir}"/usr/share/sip/python2-PyKDE4
# Use the python2 executable
find "${pkgdir}" -name '*.py' | xargs sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|'
}
|
