blob: bbccfc541b8dc12b2f88950ca747b442c5d561d7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# $Id: PKGBUILD 101521 2013-11-26 23:05:03Z alucryd $
# Maintainer: Maxime Gauduin <alucryd@gmail.com>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: BlackEagle <ike.devolder@gmail.com>
# Contributor: Dany Martineau <dany.luc.martineau@gmail.com>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
# Contributor (Parabola): Kete <kete@ninthfloor.org>
# Contributor (Parabola): Márcio Silva <coadde@lavabit.com>
_pkgname=clementine
pkgname=clementine-libre
pkgver=1.2.1
pkgrel=1
pkgdesc="A music player and library organizer, without nonfree artwork and spotify support"
url="http://www.clementine-player.org/"
license=('GPL')
arch=('i686' 'x86_64')
depends=('chromaprint' 'glew' 'gstreamer0.10-base' 'libcdio' 'libgpod' 'liblastfm' 'libmtp' 'libmygpo-qt' 'protobuf' 'qca-ossl' 'taglib')
makedepends=('cmake' 'boost' 'mesa' 'sparsehash')
optdepends=('gstreamer0.10-base-plugins: "Base" plugin libraries'
'gstreamer0.10-good-plugins: "Good" plugin libraries'
'gstreamer0.10-bad-libre-plugins: "Bad" plugin libraries'
'gstreamer0.10-ugly-plugins: "Ugly" plugin libraries'
'gvfs: Various devices support')
replaces=('clementine')
conflicts=('clementine')
provides=("clementine=$pkgver")
install=clementine.install
source=("https://repo.parabolagnulinux.org/sources/${pkgname}-${pkgver}.tar.gz")
sha256sums=('c376dd2cc346ad1f9828d3731e2bfb03cd0b4d06ea2b23d4b2caaf9351812ec2')
mksource=("http://clementine-player.googlecode.com/files/${_pkgname}-${pkgver}.tar.gz"
'remove-nonfree-artwork-and-spotify.patch'
'moognu.png')
mksha256sums=('db556e8bf230e2535636f5736a62ffe24ce154481fb05123e8395ab4aa64654e'
'13c12cb47a9bb4585014512ebf2c9e81f8ab35afee255f35360acb0f388e21db'
'c6918617769152f3617c61f721819e69d03f671b85760b11cfe45abd53955bc4')
mksource() {
cd ${_pkgname}-${pkgver}
# remove nonfree nonfree artwork and spotify references on files
patch -Np1 -i ../remove-nonfree-artwork-and-spotify.patch
# remove nonfree spotifyblob folders
rm -rv ext/{clementine-spotifyblob,libclementine-spotifyblob}
# remove nonfree spotify files
rm -v cmake/SpotifyVersion.cmake
rm -v data/spotify-attribution.png
rm -v data/icons/svg/spotify.svg
rm -v data/schema/schema-30.sql
rm -v src/{globalsearch/spotifysearchprovider.{cpp,h},internet/spotify{blobdownloader.{cpp,h},server.{cpp,h},service.{cpp,h},settingspage.{cpp,h,ui}}}
## remove nonfree nyancat.png
rm -v data/nyancat.png
## rut moognu.png to the source code
install -m644 -v ../moognu.png data
# create a blank file due which is a dependency for clementine
touch data/schema/schema-30.sql
}
build() {
cd ${_pkgname}-${pkgver}
if [[ -d build ]]; then
rm -rf build
fi
mkdir build && cd build
cmake .. -DCMAKE_INSTALL_PREFIX='/usr' -DCMAKE_BUILD_TYPE='Release'
make
}
package() {
cd ${_pkgname}-${pkgver}/build
make DESTDIR="${pkgdir}" install
}
# vim: ts=2 sw=2 et:
|
