blob: 87ddae50b00254ea087a4f65603272760f5df328 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 89175 2013-04-27 13:22:02Z ioni $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
_pkgbasename=cairo
pkgname=lib32-$_pkgbasename
pkgver=1.12.14
pkgrel=4
pkgdesc="Cairo vector graphics library (32-bit)"
arch=('x86_64')
url="http://cairographics.org/"
license=('LGPL' 'MPL')
makedepends=('gcc-multilib' 'lib32-gtk2' 'lib32-mesa>=9.1' 'lib32-mesa-libgl>=9.1' 'mesa-libgl') # we need to avoid old libgl in [extra]
source=(http://cairographics.org/releases/${_pkgbasename}-${pkgver}.tar.xz
libpng16.patch)
options=(!libtool)
sha1sums=('9106ab09b2e7b9f90521b18dd4a7e9577eba6c15'
'c9911f185637d266ce1d2985bd6fb7d0df3d75b2')
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd "${srcdir}/${_pkgbasename}-${pkgver}"
patch -Np1 -i ../libpng16.patch
./configure --prefix=/usr \
--libdir=/usr/lib32 \
--sysconfdir=/etc \
--localstatedir=/var \
--disable-static \
--enable-tee \
--enable-gl \
--enable-egl
# --disable-xlib-xcb
make
}
package() {
depends=('lib32-libpng' 'lib32-libxext' 'lib32-libxrender' 'lib32-fontconfig'
'lib32-pixman' 'lib32-glib2' 'lib32-mesa>=9.1' 'lib32-libgl' ${_pkgbasename})
cd "${srcdir}/${_pkgbasename}-${pkgver}"
make DESTDIR="${pkgdir}" install
rm -rf "${pkgdir}"/usr/{include,share,bin}
}
|