blob: b99ad482e359e95c7c92f3fa7a901a77bb7f3d68 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 72982 2012-06-26 12:34:29Z bluewind $
# Maintainer : Ionut Biru <ibiru@archlinux.org>
pkgname=lib32-dbus-core
_pkgbasename=dbus-core
pkgver=1.6.0
pkgrel=1
pkgdesc="Freedesktop.org message bus system (32-bit)"
arch=('x86_64')
url="http://www.freedesktop.org/Software/dbus"
license=('GPL' 'custom')
depends=('lib32-glibc' 'lib32-expat' 'dbus-core')
makedepends=('gcc-multilib' lib32-libx11)
options=(!libtool)
source=(http://dbus.freedesktop.org/releases/dbus/dbus-${pkgver}.tar.gz)
md5sums=('16dcae2dd0c76e398381601ac9acdec4')
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd "${srcdir}/dbus-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libdir=/usr/lib32 \
--libexecdir=/usr/lib/dbus-1.0 --with-dbus-user=81 \
--with-system-pid-file=/var/run/dbus.pid \
--enable-inotify --disable-dnotify \
--disable-verbose-mode --disable-static \
--disable-tests --disable-asserts --disable-systemd
make
}
package() {
cd "${srcdir}/dbus-${pkgver}"
make DESTDIR=${pkgdir} install
rm -rf "${pkgdir}"/usr/{bin,include,lib,share}
rm -rf "${pkgdir}"/{etc,var}
mkdir -p "${pkgdir}/usr/share/licenses"
ln -s ${_pkgbasename} "${pkgdir}/usr/share/licenses/${pkgname}"
}
|
