blob: c9a313f09db71d175e67825fa1eca53cc54703eb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 35315 2010-12-18 20:32:19Z ibiru $
# Maintainer: Biru Ionut <ionut@archlinux.ro
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Contributor: Mikko Seppälä <t-r-a-y@mbnet.fi>
_pkgbasename=gnutls
pkgname=lib32-$_pkgbasename
pkgver=2.10.4
pkgrel=1
pkgdesc="A library which provides a secure layer over a reliable transport layer (32-bit)"
arch=('x86_64')
license=('GPL3' 'LGPL')
url="http://www.gnu.org/software/gnutls/"
options=('libtool')
# uses built-in libtasn1 for the moment
depends=(lib32-{gcc-libs,readline,libgcrypt,zlib})
makedepends=('gcc-multilib')
source=(ftp://ftp.gnu.org/gnu/gnutls/${_pkgbasename}-${pkgver}.tar.bz2)
md5sums=('4e1517084018a8b1fdc96daabea40528')
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd ${srcdir}/${_pkgbasename}-${pkgver}
./configure --prefix=/usr --libdir=/usr/lib32 \
--with-zlib --disable-guile
make
}
package() {
cd "${srcdir}/${_pkgbasename}-${pkgver}"
make DESTDIR="${pkgdir}" install
rm -rf "${pkgdir}"/usr/{bin,include,share}
}
|
