blob: c207fce68050b1d0b88c6d6f0d13545a37ac827d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 66056 2012-02-22 16:55:31Z bluewind $
# Maintainer: Florian Pritz <bluewind@xinu.at>
# Contributor: Christoph Vigano <mail at cvigano dot de>
# Contributor: Biru Ionut <ionut@archlinux.ro>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Contributor: Mikko Seppälä <t-r-a-y@mbnet.fi>
_pkgbasename=gnutls
pkgname=lib32-$_pkgbasename
pkgver=3.0.13
pkgrel=1
pkgdesc="A library which provides a secure layer over a reliable transport layer (32-bit)"
arch=('x86_64')
license=('GPL3' 'LGPL')
url="http://www.gnu.org/software/gnutls/"
options=('!libtool')
depends=('lib32-zlib' 'lib32-nettle>=2.4' 'lib32-p11-kit>=0.11' $_pkgbasename)
makedepends=('gcc-multilib' 'lib32-libidn')
source=(ftp://ftp.gnu.org/gnu/gnutls/${_pkgbasename}-${pkgver}.tar.xz buildfix.diff)
md5sums=('ec549be557f31ea8c1738cb441ef23ec' '9b2a32b41391d95aeb8ddae3756fa191')
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd ${srcdir}/${_pkgbasename}-${pkgver}
patch -Np1 -i ${srcdir}/buildfix.diff
# build fails without --disable-hardware-acceleration because of assembler errors
./configure --prefix=/usr --libdir=/usr/lib32 \
--with-zlib \
--disable-static \
--disable-guile \
--disable-valgrind-tests --disable-hardware-acceleration
make
}
package() {
cd "${srcdir}/${_pkgbasename}-${pkgver}"
make DESTDIR="${pkgdir}" install
find $pkgdir
rm -rf "${pkgdir}"/usr/{bin,include,share}
}
|
