blob: 067f0eb1ecdada737ac49092959d636626e1fdea (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# $Id: PKGBUILD 41464 2011-03-06 21:01:51Z schiv $
# Maintainer: tobias <tobias@archlinux.net>
# Maintainer: Ray Rashif <schivmeister@gmail.com>
# Contributor: Robert Emil Berge <robert@rebi.no>
_pkgbasename=jack
pkgname=lib32-$_pkgbasename
_longname=jack-audio-connection-kit
pkgver=0.120.1
pkgrel=1
pkgdesc="A low-latency audio server (32-bit)"
arch=('x86_64')
license=('GPL' 'LGPL')
depends=('lib32-glibc' $_pkgbasename)
makedepends=(gcc-multilib)
url="http://jackaudio.org/"
options=('!libtool')
source=(http://jackaudio.org/downloads/${_longname}-${pkgver}.tar.gz)
md5sums=('e45bab906be64e4e2752cbd855a8efd5')
build() {
cd ${srcdir}/${_longname}-${pkgver}
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
./configure --prefix=/usr --libdir=/usr/lib32
make -C libjack
}
package() {
cd ${srcdir}/${_longname}-${pkgver}
make DESTDIR=${pkgdir} install-pkgconfigDATA
make -C libjack DESTDIR=${pkgdir} install
}
# vim:set ts=2 sw=2 et:
|
