blob: 232afa4568c13638caf5c24d75a60a7236298d4e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# $Id: PKGBUILD 35267 2010-12-18 01:14:35Z heftig $
# Maintainer: Jan de Groot <jgc@archlinux.org>
_pkgbasename=libx11
pkgname=lib32-$_pkgbasename
pkgver=1.4.0
pkgrel=1
pkgdesc="X11 client-side library (32-bit)"
arch=(x86_64)
url="http://xorg.freedesktop.org/"
depends=('lib32-libxcb' 'xproto' 'kbproto' $_pkgbasename)
makedepends=('xorg-util-macros' 'xextproto' 'xtrans' 'inputproto' 'gcc-multilib')
options=('!libtool')
license=('custom:XFREE86')
source=(${url}/releases/individual/lib/libX11-${pkgver}.tar.bz2)
sha1sums=('3d198f5578733d6c3d81c005025875f6d084668e')
build() {
export CC="gcc -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd "${srcdir}/libX11-${pkgver}"
./configure --prefix=/usr --disable-static --disable-xf86bigfont \
--libdir=/usr/lib32 --disable-specs
make
make check
}
package() {
cd "${srcdir}/libX11-${pkgver}"
make DESTDIR="${pkgdir}" install
rm -rf "${pkgdir}"/usr/{include,share}
mkdir -p "$pkgdir/usr/share/licenses"
ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}
|
