blob: d05c4ce39649fc4abcc799a1a228cafe41ded811 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# $Id: PKGBUILD 67394 2012-03-11 10:50:08Z bluewind $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
_pkgbasename=libxft
pkgname=lib32-$_pkgbasename
pkgver=2.3.0
pkgrel=1
pkgdesc="FreeType-based font drawing library for X (32-bit)"
arch=('x86_64')
license=('custom')
url="http://xorg.freedesktop.org/"
depends=('lib32-fontconfig' 'lib32-libxrender')
makedepends=('gcc-multilib')
options=('!libtool')
source=(${url}/releases/individual/lib/libXft-${pkgver}.tar.bz2)
sha1sums=('687f38a810b9ae58e1169c295d9d438370235e23')
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd ${srcdir}/libXft-${pkgver}
./configure --prefix=/usr \
--libdir=/usr/lib32 --disable-static
make
}
package() {
cd "${srcdir}/libXft-${pkgver}"
make DESTDIR="${pkgdir}" install
rm -rf "${pkgdir}"/usr/{bin,include,share}
mkdir -p "$pkgdir/usr/share/licenses"
ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}
|
