blob: d181f3b9f6e67dd722e0b4132eb6a4b2f825fe0c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# $Id: PKGBUILD 186656 2013-05-30 12:19:35Z dreisner $
# Contributor: FUBAR <mrfubar@gmail.com>
# Contributor: simo <simo@archlinux.org>
# Contributor: Jeff 'codemac' Mickey <jeff@archlinux.org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Maintainer: Dave Reisner <dreisner@archlinux.org>
_pkgname=bitlbee
pkgname=bitlbee-nonprism
pkgver=3.2
pkgrel=3
pkgdesc='Brings XMPP to IRC, without support for unsafe and dangerous for privacy protocols'
url='http://www.bitlbee.org/'
license=('GPL')
arch=('i686' 'x86_64')
depends=('gnutls' 'glib2')
makedepends=('asciidoc' 'libotr3')
optdepends=('libotr3: for OTR encryption support'
'xinetd: to run bitlbee through xinetd')
replaces=("$_pkgname" 'bitlbee-coherence')
conflicts=$_pkgname
provides=$_pkgname=$pkgver
source=("http://get.bitlbee.org/src/${_pkgname}-${pkgver}.tar.gz"
'xinetd'
'bitlbee.tmpfiles')
sha1sums=('21e17f082c776566429603b1e8c966983a75ac9e'
'81c1185b09bee9520b7b58e295a0ffe43a9b0093'
'64b05c7ba522fcdbd0fb57d89ea8320713cc18e9')
backup=('etc/bitlbee/bitlbee.conf'
'etc/bitlbee/motd.txt'
'etc/xinetd.d/bitlbee')
install=bitlbee.install
build() {
cd "$_pkgname-$pkgver"
./configure \
--prefix=/usr \
--etcdir=/etc/bitlbee \
--sbindir=/usr/bin \
--pidfile=/run/bitlbee/bitlbee.pid \
--ipcsocket=/run/bitlbee/bitlbee.sock \
--systemdsystemunitdir=/usr/lib/systemd/system \
--jabber=1 \
--msn=0 \
--oscar=0 \
--yahoo=0 \
--twitter=0 \
--purple=0 \
--ssl=gnutls \
--strip=0 \
--otr=plugin \
--skype=0
# hacky: build against libotr3
sed -i 's,^OTRFLAGS=.*,OTRFLAGS=-lotr3,' Makefile.settings
sed -i 's,#include.*libotr,&3,' otr.h
make
}
package() {
make -C "$_pkgname-$pkgver" DESTDIR="$pkgdir" install{,-etc,-dev}
install -o65 -g65 -dm770 "$pkgdir/var/lib/bitlbee"
install -Dm644 "$srcdir/xinetd" "$pkgdir/etc/xinetd.d/bitlbee"
install -Dm644 "$srcdir/bitlbee.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/bitlbee.conf"
}
|
