blob: 9c291afb741a3389e03ec22a6acdce267da5b00c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# $Id: PKGBUILD 120010 2011-04-18 10:28:14Z pierre $
# Maintainer: Angel Velasquez <angvp@archlinux.org>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Lucien Immink <l.immink@student.fnt.hvu.nl>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
pkgname=curl
pkgver=7.21.5
pkgrel=2
pkgdesc="An URL retrival utility and library"
arch=('i686' 'x86_64')
url="http://curl.haxx.se"
license=('MIT')
depends=('zlib' 'openssl' 'bash' 'ca-certificates')
options=('!libtool')
source=(http://curl.haxx.se/download/${pkgname}-${pkgver}.tar.bz2
curlbuild.h curl-config-fix-version.patch)
md5sums=('dadd6353c9407161ddd62c0943718d59'
'751bd433ede935c8fae727377625a8ae'
'b1c1705887db11e4a04f4dcd997a768a')
[[ $CARCH == "x86_64" ]] && _curlbuild=curlbuild-64.h
[[ $CARCH == "i686" ]] && _curlbuild=curlbuild-32.h
build() {
cd ${srcdir}/${pkgname}-${pkgver}
patch -p1 -i ${srcdir}/curl-config-fix-version.patch
./configure \
--with-random=/dev/urandom \
--prefix=/usr \
--mandir=/usr/share/man \
--disable-dependency-tracking \
--enable-ipv6 \
--disable-ldaps \
--disable-ldap \
--enable-manual \
--enable-versioned-symbols \
--with-ca-bundle=/etc/ssl/certs/ca-certificates.crt \
--without-libidn \
--enable-threaded-resolver
make
}
package() {
cd ${srcdir}/${pkgname}-${pkgver}
make DESTDIR=${pkgdir} install
install -Dm644 COPYING \
${pkgdir}/usr/share/licenses/${pkgname}/COPYING
install -Dm644 docs/libcurl/libcurl.m4 \
${pkgdir}/usr/share/aclocal/libcurl.m4
mv "${pkgdir}/usr/include/curl/curlbuild.h" "${pkgdir}/usr/include/curl/${_curlbuild}"
install -m 644 ${srcdir}/curlbuild.h "${pkgdir}/usr/include/curl/curlbuild.h"
}
|
