blob: c0bab91ef6453d9da08a50378cf599a647c10821 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id: PKGBUILD 119782 2011-04-15 08:31:34Z jgc $
# Maintainer: tobias <tobias@archlinux.org>
pkgname=gimp
pkgver=2.6.11
pkgrel=5
pkgdesc="GNU Image Manipulation Program"
arch=('i686' 'x86_64')
url="http://www.gimp.org/"
license=('GPL')
depends=('gtk2' 'lcms' 'libxpm' 'libwmf' 'libxmu' 'librsvg' 'libmng' 'dbus-glib' \
'libexif' 'pygtk' 'desktop-file-utils' 'gegl')
makedepends=('gutenprint' 'intltool' 'libwebkit' 'gnome-python' 'poppler-glib' \
'pkg-config' 'alsa-lib' 'iso-codes')
optdepends=('gutenprint: for sophisticated printing only as gimp has built-in cups print support'
'libwebkit: for the help browser'
'poppler-glib: for pdf support'
'alsa-lib: for MIDI event controller module')
options=('!libtool' '!makeflags')
conflicts=('gimp-devel')
install=gimp.install
source=(ftp://ftp.gimp.org/pub/gimp/v${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2 linux.gpl)
md5sums=('bb2939fe13e54fc7255cef5d097bb5dd'
'bb27bc214261d36484093e857f015f38')
sha1sums=('2f9d596e727bdbf304fa78257c1731d9faf3934c'
'110ce9798173b19a662d086ed7b882b4729f06cf')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc \
--enable-mp --enable-gimp-console --enable-gimp-remote \
--enable-python --with-gif-compression=lzw \
--without-aa --without-hal
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install-strip
sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' "${pkgdir}"/usr/lib/gimp/2.0/plug-ins/*.py
install -D -m644 "${srcdir}/linux.gpl" "${pkgdir}/usr/share/gimp/2.0/palettes/Linux.gpl"
rm "${pkgdir}/usr/share/man/man1/gimp-console.1"
ln -s gimp-console-${pkgver%.*}.1.gz "${pkgdir}/usr/share/man/man1/gimp-console.1.gz"
ln -s gimptool-2.0 "${pkgdir}/usr/bin/gimptool"
ln -sf gimptool-2.0.1.gz "${pkgdir}/usr/share/man/man1/gimptool.1.gz"
}
|
