blob: 09386a73fef713fe3b4f78a320bd0420985d0146 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# $Id: PKGBUILD 140411 2011-10-13 03:56:02Z schiv $
# Maintainer: Ray Rashif <schivmeister@gmail.com>
# Contributor: galiyosha@gmail.com
# Contributor: Jon Kristian Nilsen <jokr.nilsen@gmail.com>
pkgname=libffado
pkgver=2.0.1
pkgrel=4
pkgdesc="Driver for FireWire audio devices"
arch=('i686' 'x86_64')
url="http://www.ffado.org/"
license=('GPL')
depends=('libiec61883' 'libavc1394' 'libsigc++'
'libxml++' 'alsa-lib' 'dbus')
makedepends=('scons' 'python2-qt')
optdepends=('python2-qt: mixer applet')
provides=('ffado')
source=("http://www.ffado.org/files/$pkgname-$pkgver.tar.gz"
'60-ffado.rules')
md5sums=('786f31facd417e6207e429f50af0e15e'
'f03a3e950801c4405b8934084651bca8')
build() {
cd "$srcdir/$pkgname-$pkgver"
# hack to use CFLAGS without optimising
sed -i 's/-O2//g' SConstruct
if [ "$CARCH" = "x86_64" ]; then
sed -i "s/-m64/-m64 $CFLAGS/g" SConstruct
else
sed -i "s/-m32/-m32 $CFLAGS/g" SConstruct
fi
# python2 fix
sed -i 's:python $SOURCE:python2 $SOURCE:' SConstruct
sed -i 's:python support/tools:python2 support/tools:' \
support/tools/SConscript
scons PREFIX=/usr #ENABLE_OPTIMIZATIONS=True
}
package() {
cd "$srcdir/$pkgname-$pkgver"
scons DESTDIR="$pkgdir/" WILL_DEAL_WITH_XDG_MYSELF="True" install
# add audio device rules
# see https://bugs.archlinux.org/task/26342
install -Dm644 "$srcdir/60-ffado.rules" \
"$pkgdir/lib/udev/rules.d/60-ffado.rules"
# python2 fix
for i in $(grep '^#!.*bin.*python' -R "$pkgdir" | sed 's/:.*//'); do
sed -i 's:^#!.*bin.*python:#!/usr/bin/python2:' "$i"
done
# desktop files & icons
install -Dm644 support/xdg/ffado.org-ffadomixer.desktop \
"$pkgdir/usr/share/applications/ffadomixer.desktop"
install -Dm644 support/xdg/hi64-apps-ffado.png \
"$pkgdir/usr/share/pixmaps/$pkgname.png"
}
# vim:set ts=2 sw=2 et:
|
