blob: f6db69266c6873211b45351c9d86401800036c7d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# $Id: PKGBUILD 168272 2012-10-07 11:37:04Z guillaume $
# Maintainer: Guillaume ALAUX <guillaume@archlinux.org>
pkgname=swt
pkgver=4.2
pkgrel=2
_date=201206081400
pkgdesc="An open source widget toolkit for Java"
arch=('i686' 'x86_64')
url="http://www.eclipse.org/swt/"
license=('EPL')
depends=('java-runtime>=6' 'gtk2>=2.20.1' 'libxtst')
optdepends=('libgnomeui' 'mesa' 'glu' 'libwebkit')
makedepends=('java-environment' 'libxtst' 'mesa' 'glu' 'libgnomeui' 'unzip' 'pkgconfig' 'libwebkit' 'apache-ant')
if [ "${CARCH}" = "i686" ]; then
_carch=x86
md5sums=('3efe0404f6129183abae46f7620fe14f'
'2f556ab534fc2488c6e8c0ee6c02825c')
fi
if [ "${CARCH}" = "x86_64" ]; then
_carch=x86_64
md5sums=('9e06b576116ff409f395571603582827'
'2f556ab534fc2488c6e8c0ee6c02825c')
fi
source=(http://download.eclipse.org/eclipse/downloads/drops4/R-${pkgver}-${_date}/swt-${pkgver}-gtk-linux-${_carch}.zip
build-swt.xml)
# To test this pkg:
# http://www.eclipse.org/swt/examples.php#standaloneOutsideEclipse
build() {
cd ${srcdir}
unzip -oq src.zip -d src
. /etc/profile.d/jdk.sh
. /etc/profile.d/apache-ant.sh
# Shared objects
cd src
./build.sh
# SWT jar
ant -f ../build-swt.xml compile
}
package() {
cd ${srcdir}/src
# Shared objects
export OUTPUT_DIR=${pkgdir}/usr/lib
install -dm755 ${OUTPUT_DIR}
make -f make_linux.mak install
# SWT jar
ant -f ../build-swt.xml jar
install -Dm755 ../swt.jar ${pkgdir}/usr/share/java/swt-${pkgver}.jar
ln -s swt-${pkgver}.jar ${pkgdir}/usr/share/java/swt.jar
}
|
