blob: 3c313b5da9b81cc00206c8b39b30756de58cd694 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 157699 2012-04-29 02:55:15Z foutrelis $
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: tobias <tobias funnychar archlinux.org>
pkgname=xfce4-session
pkgver=4.10.0
pkgrel=1
pkgdesc="A session manager for Xfce"
arch=('i686' 'x86_64')
url="http://www.xfce.org/"
license=('GPL2')
groups=('xfce4')
# keep xorg-server-utils for https://bugs.archlinux.org/task/21096
# upower and consolekit for reboot/shutdown/hibernate/suspend
depends=('libxfce4ui' 'libgnome-keyring' 'libwnck' 'libsm' 'xorg-iceauth'
'upower' 'consolekit' 'hicolor-icon-theme')
makedepends=('intltool')
optdepends=('fortune-mod: for xfce4-tips')
replaces=('xfce-utils')
options=('!libtool')
install=$pkgname.install
source=(http://archive.xfce.org/src/xfce/$pkgname/4.10/$pkgname-$pkgver.tar.bz2)
sha256sums=('bb8aa9a74c3d382840596fb4875144d66c7f3f47c8e9ee81d31e3428a72c46ce')
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure --prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/xfce4 \
--localstatedir=/var \
--disable-static \
--enable-libgnome-keyring \
--disable-debug
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
}
# vim:set ts=2 sw=2 et:
|
