spacefm-libre: add new package to [libre]

1 files changed, 51 insertions, 0 deletions

diff --git a/libre/spacefm-libre/PKGBUILD b/libre/spacefm-libre/PKGBUILD
new file mode 100644
index 000000000..10b6cec15
--- /dev/null
+++ b/libre/spacefm-libre/PKGBUILD
@@ -0,0 +1,51 @@
+# $Id: PKGBUILD 108682 2014-04-01 08:51:32Z bpiotrowski $
+# Maintainer (Arch):  Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
+# Contributor (Arch): IgnorantGuru http://igurublog.wordpress.com/contact-ignorantguru/
+# Contributor (Arch): ridikulus_rat <the.ridikulus.rat@gmail.com>
+# Maintainer: André Silva <emulatorman@parabola.nu>
+# Contributor: Edison Ibañez <arkhan.xxx@gmail.com>
+
+_pkgname=spacefm
+pkgname=spacefm-libre
+pkgver=0.9.4
+pkgrel=1
+pkgdesc='Multi-panel tabbed file manager, with unar support'
+arch=('i686' 'x86_64')
+url='http://ignorantguru.github.com/spacefm/'
+license=('GPL3')
+install=$_pkgname.install
+depends=('gtk3' 'shared-mime-info' 'desktop-file-utils' 'startup-notification'
+         'systemd' 'bash' 'unar')
+makedepends=('intltool' 'gettext')
+optdepends=('lsof: device processes'
+            'wget: plugin download'
+            'gksu: perform as root functionality'
+            'udevil: mount as non-root user and mount networks'
+            'udisks: mount as non-root user'
+            'udisks2: mount as non-root user')
+replaces=($_pkgname)
+conflicts=($_pkgname)
+provides=($_pkgname=$pkgver)
+source=(https://github.com/IgnorantGuru/spacefm/archive/$pkgver.tar.gz
+        libre.patch)
+md5sums=('daeee7dcccea33d6258a0a9d783470c4'
+         '30ba2b4b8f5ae7bf1552689b192eab89')
+
+prepare() {
+  # replace nonfree unrar with unar support
+  cd $_pkgname-$pkgver
+  patch -Np1 -i $srcdir/libre.patch src/ptk/ptk-file-archiver.c
+}
+
+build() {
+  cd $_pkgname-$pkgver
+  ./configure --prefix=/usr \
+    --disable-pixmaps \
+    --with-gtk3
+  make
+}
+
+package() {
+  cd $_pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}