sddm-consolekit: add new package to [pcr]

1 files changed, 47 insertions, 0 deletions

diff --git a/pcr/sddm-consolekit/PKGBUILD b/pcr/sddm-consolekit/PKGBUILD
new file mode 100644
index 000000000..7252cab46
--- /dev/null
+++ b/pcr/sddm-consolekit/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer           : freaj <freaj@riseup.net>
+# Maintainer  (Manjaro): artoo <artoo@manjaro.org>
+# Contributor (Manjaro): Andrea Scarpino <andrea@archlinux.org>
+
+_pkgname=sddm
+
+pkgname=sddm-consolekit
+pkgver=0.11.0
+pkgrel=1
+pkgdesc='QML based X11 display manager'
+arch=('i686' 'x86_64')
+url='http://github.com/sddm/sddm'
+license=('GPL')
+depends=('qt5-declarative')
+makedepends=('cmake' 'python-docutils' 'qt5-tools')
+install="${_pkgname}.install"
+backup=('usr/share/sddm/scripts/Xsetup')
+conflicts=('display-manager' 'sddm')
+provides=('display-manager' 'sddm')
+source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/${_pkgname}/${_pkgname}/archive/v${pkgver}.tar.gz"
+        "${_pkgname}-consolekit.patch"
+        "${_pkgname}-upower.patch")
+sha256sums=('80d53f075c275f744bd547523d6d640baccfacb4e463a71ec0facb8231b832ce'
+            '4cbe522c84956d13d751856b8c66f2beca210c9ec65712e261bfe2bf94fb0da5'
+            '6a2efbc0cd65d8f63a3f1288051001b18da5d00f5ce0ddbac1656a69c3a1a29f')
+
+prepare() {
+  mkdir -p build
+  cd ${_pkgname}-${pkgver}
+  patch -p1 -i ${srcdir}/${_pkgname}-consolekit.patch
+  patch -p1 -i ${srcdir}/${_pkgname}-upower.patch
+}
+
+build() {
+  cd build
+  cmake ../${_pkgname}-${pkgver} \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DCMAKE_INSTALL_LIBEXECDIR=/usr/lib/sddm \
+        -DBUILD_MAN_PAGES=ON
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="${pkgdir}" install
+}