move ~lukeshu-closure-compiler/{,java-}jarjar

2 files changed, 81 insertions, 0 deletions

diff --git a/~lukeshu-closure-compiler/java-jarjar/PKGBUILD b/~lukeshu-closure-compiler/java-jarjar/PKGBUILD
new file mode 100644
index 000000000..31f374427
--- /dev/null
+++ b/~lukeshu-closure-compiler/java-jarjar/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
+
+_pkgname=jarjar
+pkgname=java-jarjar
+pkgver=1.1
+pkgrel=1
+pkgdesc="A utility that makes it easy to repackage Java libraries and embed them into your own distribution."
+arch=('any')
+url="https://code.google.com/p/jarjar/"
+license=('Apache2')
+depends=('java-runtime')
+makedepends=('apache-ant' 'java-asm' 'maven')
+source=("http://repo.parabolagnulinux.org/other/${pkgname}-${pkgver}-${pkgrel}-any.src.tar.xz")
+
+build() {
+  cd "$srcdir/$pkgname"
+
+  ln -s /usr/share/java/asm/asm-3.3.1.jar lib
+  ln -s /usr/share/java/asm/asm-commons-3.3.1.jar lib
+  ln -s /opt/maven/lib/maven-plugin-api-*.jar lib/maven-plugin-api.jar
+
+  # Define the version
+  sed -i "s/snapshot/$pkgver/" build.xml
+
+  # Fix a bug causing an incompatibility with newer versions of ant
+  sed -i 's/zipDir(null,/zipDir((java.io.File)null,/' \
+      src/main/com/tonicsystems/jarjar/util/AntJarProcessor.java
+
+  ant jar
+}
+
+package() {
+  cd "$srcdir/$pkgname"
+  install -d "$pkgdir/usr/share/java/$_pkgname"
+  install -D "dist/$_pkgname-$pkgver.jar" "$pkgdir/usr/share/java/$_pkgname"
+  ln -s "$pkgname/$_pkgname-$pkgver.jar" "$pkgdir/usr/share/java/$_pkgname.jar"
+}
+
+md5sums=('af46c24b90d009169b7f83ee1e8bbd9c')
diff --git a/~lukeshu-closure-compiler/java-jarjar/SRCBUILD b/~lukeshu-closure-compiler/java-jarjar/SRCBUILD
new file mode 100644
index 000000000..b716eeb51
--- /dev/null
+++ b/~lukeshu-closure-compiler/java-jarjar/SRCBUILD
@@ -0,0 +1,42 @@
+# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
+
+_pkgname=jarjar
+pkgname=java-jarjar
+pkgver=1.1
+pkgrel=1
+pkgdesc="A utility that makes it easy to repackage Java libraries and embed them into your own distribution."
+arch=('any')
+url="https://code.google.com/p/jarjar/"
+license=('Apache2')
+makedepends=('subversion' 'findutils')
+options=('!strip' 'docs' '!zipman' 'emptydirs')
+
+_svntrunk="https://jarjar.googlecode.com/svn/tags/release-$pkgver/$_pkgname"
+_svnver=131
+
+build() {
+  cd "$srcdir"
+  msg "Connecting to SVN server...."
+
+  if [[ -d "$pkgname/.svn" ]]; then
+    (cd "$pkgname" && svn up -r "$_svnver")
+  else
+    svn co "$_svntrunk" --config-dir ./ -r "$_svnver" "$pkgname"
+  fi
+
+  msg "SVN checkout done or server timeout"
+
+  msg "Removing .svn files..."
+  find . -name .svn -print0 | xargs -0 rm -rf
+
+  msg "Removing precompiled binaries..."
+  cd "$srcdir/$pkgname"
+  rm -v src/test/*.class src/test/*.jar
+  rm -v lib/*.jar
+}
+
+package() {
+  PKGEXT=${SRCEXT}
+  PKGDEST=${SRCDEST}
+  cp -a "${srcdir}/${pkgname}" "${pkgdir}/"
+}