blob: 42a33a1136f9e884559e1a949b9d477bebf0a5ce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 183193 2013-04-18 17:14:00Z andyrtr $
# Maintainer: tobias <tobias@archlinux.org>
# Contributor: Low Kian Seong <fastmail_low@speedymail.org>
_pkgname=bogofilter
pkgname=bogofilter-libre
pkgver=1.2.3
pkgrel=1
pkgdesc="A fast Bayesian spam filtering tool, without noncommercial files"
arch=('i686' 'x86_64')
license=('GPL3')
url="http://bogofilter.sourceforge.net"
depends=('db' 'perl' 'gsl')
backup=('etc/bogofilter/bogofilter.cf')
source=(http://sourceforge.net/projects/${_pkgname}/files/${_pkgname}-current/${_pkgname}-${pkgver}/${_pkgname}-${pkgver}.tar.bz2)
md5sums=('c3ed7f483b83abcbf6d8c797084bd06e')
provides=("${_pkgname}=${pkgver}")
replaces=("${_pkgname}")
conflicts=("${_pkgname}")
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
# Remove noncommercial files.
rm doc/bogofilter-SA-{2005-0{1,2},2010-01}
./configure --prefix=/usr \
--sysconfdir=/etc/bogofilter \
--localstatedir=/var \
--enable-transactions
make
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
mv "${pkgdir}/etc/bogofilter/bogofilter.cf.example" "${pkgdir}/etc/bogofilter/bogofilter.cf"
install -dm755 "${pkgdir}/usr/share/${_pkgname}/contrib"
install -m644 contrib/* "${pkgdir}/usr/share/${_pkgname}/contrib/"
}
|
