blob: c8f98dadf99f15bf1c9681a6ab4a9f1d0ef908d4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id: PKGBUILD 199462 2013-11-13 08:34:51Z schiv $
# Maintainer: Ray Rashif <schiv@archlinux.org>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
_pkgname=ecasound
pkgname=ecasound-libre
pkgver=2.9.0
pkgrel=4
pkgdesc="A software package designed for multitrack audio processing, without nonfree faac recommendation"
arch=('i686' 'x86_64')
url="http://www.eca.cx/ecasound/"
license=('GPL' 'LGPL')
depends=('audiofile' 'liblo' 'liboil' 'lilv')
makedepends=('python2' 'ruby')
optdepends=('python2: ecamonitor, ECI API'
'ruby: ECI API'
'mpg123: MP3 decoding'
'lame: MP3 encoding'
'vorbis-tools: Ogg Vorbis decoding/encoding'
'faad2: AAC decoding'
'timidity++: MIDI file input'
'libmikmod: tracker module')
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
source=("http://ecasound.seul.org/download/$_pkgname-$pkgver.tar.gz"
'ruby2.patch')
md5sums=('05e7d4664cdf4c7a138c098e9506a551'
'6909dbd4f67f76d3bd31ce7c7fe16212')
build() {
cd "$srcdir/$_pkgname-$pkgver"
# fix ruby 2.0 incompatibility + use vendor_ruby for ruby files
patch -Np1 -i "$srcdir/ruby2.patch"
PYTHONPATH=/usr/bin/python2 ./configure \
--prefix=/usr \
--with-python-includes=/usr/include/python2.7 \
--with-python-modules=/usr/lib/python2.7
make
}
package() {
cd "$srcdir/$_pkgname-$pkgver"
make DESTDIR="$pkgdir/" install
# fix for python 2.7
sed -i 's:bin/env python:bin/env python2:' \
"$pkgdir/usr/bin/ecamonitor"
}
# vim:set ts=2 sw=2 et:
|
