blob: 512ef367945241b9c9ac13059350ff66e214be32 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer (Arch): Muflone http://www.muflone.com/contacts/english/
# Contributor (Arch): Diego Principe <cdprincipe@at@gmail@dot@com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Daniel Milewski <niitotantei@riseup.net>
pkgname=icecat-theme-adwaita
pkgver=38.1
pkgrel=1.1
pkgdesc="Adwaita theme for IceCat (Matches the default GNOME Shell theme)"
url="https://addons.mozilla.org/en-US/firefox/addon/adwaita/"
arch=('any')
license=('MPL')
depends=("icecat")
makedepends=('unzip')
source=("gnome-firefox-theme-${pkgver}.xpi"::"https://github.com/gnome-integration-team/firefox-gnome/releases/download/${pkgver}/gnome-firefox-theme.xpi")
sha256sums=('af050237a8cddee0f9123f81a9df58b0b97e94f84059cc67225183cb3243a70e')
noextract=("gnome-firefox-theme-${pkgver}.xpi")
prepare() {
unzip -qo "gnome-firefox-theme-${pkgver}.xpi" -d "${pkgname}-${pkgver}"
# Fix for wrong version number
# https://github.com/gnome-integration-team/firefox-gnome/issues/337
cd "${pkgname}-${pkgver}"
sed -i "s_\(<em:version>\)35.1\(</em:version>\)_\1${pkgver}\2_" "install.rdf"
}
package() {
cd "${pkgname}-${pkgver}"
# Find extension UUID
_emid=$(sed -n '/.*<em:id>\(.*\)<\/em:id>.*/{s//\1/p;q}' install.rdf)
# Prepare destination folder
_dstdir="${pkgdir}/usr/lib/icecat/browser/extensions/${_emid}"
install -d "${_dstdir}"
# Copy files
cp -R * "${_dstdir}"
# Restore standard permissions
find "${pkgdir}" -type d -print0 | xargs --null chmod 0755
find "${pkgdir}" -type f -print0 | xargs --null chmod 0644
}
|
