blob: c50eb3a13679bdf2304bc212d1fa75a2f5006a7d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# $Id: PKGBUILD 255801 2015-12-11 22:30:55Z arojas $
# Maintainer (Arch): Ronald van Haren <ronald@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>
pkgbase=digikam
pkgname=kipi-plugins
pkgver=4.14.0
pkgrel=4.parabola1
pkgdesc="A collection of plugins extending the KDE graphics and image applications as digiKam, without nonfree jAlbum and SimpleViewer support"
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.digikam.org/"
replaces=("${pkgname}-libre")
conflicts=("${pkgname}-libre")
makedepends=('kdepimlibs4' 'libkexiv2_4' 'libkdcraw4' 'libkipi4' 'libksane4' 'liblqr'
'opencv' 'boost' 'libgpod' 'libkvkontakte' 'hugin' 'libgphoto2'
'cmake' 'automoc4' 'doxygen' 'lensfun' 'qt4-gstreamer' 'imagemagick' 'eigen'
'libbaloo4' 'libpgf' 'libusb-compat' 'libkface4' 'libkgeomap4' 'libmediawiki' 'clang')
depends=('kdebase-runtime' 'kdepimlibs4' 'libkdcraw4' 'libkipi4' 'libksane4' 'libkexiv2_4')
optdepends=('libkgeomap4: Geolocalize tool'
'libmediawiki: MediaWiki Export plugin'
'libkvkontakte: VKontakte.ru Exporter plugin'
'libgpod: iPodExport plugin'
'opencv: Remove Red Eyes plugin'
'imagemagick: Video SlideShow plugin'
'qt4-gstreamer: Video SlideShow plugin'
'hugin: panorama tools')
options=('staticlibs')
install=kipi-plugins.install
source=("http://download.kde.org/stable/${pkgbase}/${pkgbase}-${pkgver}.tar.bz2")
sha1sums=('08bbded5433e442dce8ac00eb301606ef0924e8c')
prepare() {
cd ${srcdir}/${pkgbase}-${pkgver}
# Fix compilation with clang
sed -i '\|fno-tree-pre|d
' core/CMakeLists.txt
sed -i '\|flashexport|d
\|jalbumexport|d
' extra/kipi-plugins/CMakeLists.txt
}
build() {
mkdir build
cd build
cmake ../${pkgbase}-${pkgver} \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_SKIP_RPATH=ON \
-DBUILD_tests=OFF \
-DCMAKE_C_COMPILER=clang # Fix build with flex 2.6
make
}
package() {
cd build/extra/kipi-plugins
make DESTDIR="${pkgdir}" install
cd ../../../build/po
make DESTDIR="${pkgdir}" install
# Put these in the relevant splitted packages
#rm "${pkgdir}"/usr/share/locale/kde4/*/LC_MESSAGES/libkgeomap.mo
rm "${pkgdir}"/usr/share/locale/kde4/*/LC_MESSAGES/digikam.mo
# Fix conflicts with kde-l10n-* (FS#33762)
rm "${pkgdir}"/usr/share/locale/kde4/*/LC_MESSAGES/libkipi.mo
cd ../../build/doc/kipi-plugins
make DESTDIR="${pkgdir}" install
}
|
