blob: 2e3126da78590d31cd5bed187266bf26c9178dfe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id$
# Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor: flixie <69one@gmx.net>
# Contributor: Imanol Celaya <ornitorrincos@archlinux-es.org>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>
pkgname=luxrender-libre
_pkgflag=libre
pkgver=1.2.1
_pkgver=3066b2161439
pkgrel=3
pkgdesc="Rendering system for physically correct, unbiased image synthesis, without nonfree OpenCL recommendation"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.${pkgname%-$_pkgflag}.net/"
license=('GPL')
depends=('boost-libs' 'freeimage' 'openexr' 'libcl' 'libgl')
optdepends=('blender-addon-luxrender: Blender for renderer and exporter' 'qt4: Qt GUI' \
'python: Python interface (pylux)')
makedepends=('cmake' 'boost' 'mesa' 'qt4' "luxrays=${pkgver::3}" 'python' 'opencl-headers')
provides=(${pkgname%-$_pkgflag}=$pkgver)
conflicts=${pkgname%-$_pkgflag}
replaces=${pkgname%-$_pkgflag}
source=(https://bitbucket.org/${pkgname%-$_pkgflag}/lux/get/$_pkgver.tar.bz2
boost-1.53-shared_array_constructor.diff)
md5sums=(
'87958798c164ad14f92fb4af2595d332'
'dd19c7ac2ba8c9b703018a176ef77f98')
build() {
cd "$srcdir"/${pkgname%-$_pkgflag}-lux-$_pkgver
# fix the installation
sed -i '/.*wxgui.*/ d' CMakeLists.txt
# fix for boost 1.53
patch -Np1 < "$srcdir/boost-1.53-shared_array_constructor.diff" || true
export CXXFLAGS="$CXXFLAGS -lpthread"
setarch $CARCH cmake -DCMAKE_INSTALL_PREFIX=/usr \
-DLUXRAYS_DISABLE_OPENCL=OFF \
-DPYTHON_CUSTOM=ON \
-DPYTHON_LIBRARIES=/usr/lib/libpython3.3m.so \
-DPYTHON_INCLUDE_PATH=/usr/include/python3.3m/ \
.
setarch $CARCH make
}
package() {
cd "$srcdir"/${pkgname%-$_pkgflag}-lux-$_pkgver
setarch $CARCH make DESTDIR="$pkgdir" install
# fix library path on x86_64
[ "$CARCH" = "x86_64" ] && mv "$pkgdir"/usr/lib64 "$pkgdir"/usr/lib
#install pylux
install -D -m644 pylux.so "$pkgdir"/usr/lib/python3.3/pylux.so
}
# vim:set ts=2 sw=2 et:
|
