blob: a59a58c3545c05db8fbdfe328b1113f673945dd6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer (Arch): Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor (Arch): flixie <69one@gmx.net>
# Contributor (Arch): Imanol Celaya <ornitorrincos@archlinux-es.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>
_pkgname=luxrender
pkgname=$_pkgname-parabola
pkgver=1.3.1
_pkgver=d0b0e20c47cc
pkgrel=10
pkgdesc='Rendering system for physically correct, unbiased image synthesis, without nonfree nvidia-utils, amdstream and intel-opencl-sdk recommendation'
arch=('i686' 'x86_64' 'mips64el')
url="http://www.$_pkgname.net/"
license=('GPL')
depends=('boost-libs' 'freeimage' 'openexr' 'libpng' 'libcl' 'libgl' 'fftw')
optdepends=('blender-addon-luxrender: Blender exporter' 'qt4: Qt GUI'
'python: pylux Python interface')
# luxrender is constantly broken to various GCC bugs, the latest one being FS#40596
#makedepends=('cmake' 'boost' 'mesa' 'qt4' "luxrays=$pkgver" 'python' 'opencl-headers')
makedepends=('cmake' 'boost' 'mesa' 'qt4' "luxrays=$pkgver" 'python')
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname" "$_pkgname-libre")
replaces=("$_pkgname" "$_pkgname-libre")
source=("https://bitbucket.org/$_pkgname/lux/get/$_pkgver.tar.bz2"
"force_python3.diff")
md5sums=('cbe749f56a1e1976745f5458100efa8a'
'42692e65eabc5828693e2682e94b7c64')
prepare() {
cd $srcdir/$_pkgname-lux-$_pkgver
patch -Np1 < $srcdir/force_python3.diff || true
# workaround QTBUG-22829
find . -type f -exec sed -i 's|^#include .*boost/.*|#ifndef Q_MOC_RUN\n&\n#endif|' '{}' ';'
}
build() {
cd $srcdir/$_pkgname-lux-$_pkgver
export CC=clang
export CXX=clang++
cmake . -DCMAKE_INSTALL_PREFIX=/usr \
-DLUXRAYS_DISABLE_OPENCL=OFF \
-DPYTHON_CUSTOM=ON \
-DPYTHON_LIBRARIES=/usr/lib/libpython3.4m.so \
-DPYTHON_INCLUDE_PATH=/usr/include/python3.4m/ \
-DCMAKE_EXE_LINKER_FLAGS=-lpthread
make
}
package() {
cd $srcdir/$_pkgname-lux-$_pkgver
make DESTDIR=$pkgdir install
# fix library path on 64bit
[[ $CARCH == x86_64 ]] && mv $pkgdir/usr/lib64 $pkgdir/usr/lib
#install pylux
install -D -m644 pylux.so $pkgdir/usr/lib/python3.4/pylux.so
}
# vim:set ts=2 sw=2 et:
|
