blob: 5ac2cbabdad55a741bc4241b3ada5cdb6dd883ed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# $Id: PKGBUILD 173594 2016-05-03 18:59:31Z alucryd $
# Maintainer (Arch): Maxime Gauduin <alucryd@archlinux.org>
# Contributor (Arch): Themaister <maister@archlinux.us>
# Contributor (Arch): lifning <definelightning@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
pkgname=retroarch
pkgver=1.3.4
pkgrel=1.parabola2
pkgdesc='Reference frontend for the libretro API, without nonfree software support, libretro-genesis-plus and libretro-snes9x recommendation'
arch=('i686' 'x86_64' 'armv7h')
url='http://www.libretro.com/'
license=('GPL')
groups=('libretro')
depends=('alsa-lib' 'glibc' 'libdrm' 'libgl' 'libpulse' 'libusb' 'libx11'
'libxcb' 'libxext' 'libxinerama' 'libxkbcommon' 'libxv' 'libxxf86vm'
'mesa' 'openal' 'python' 'sdl2' 'wayland' 'zlib'
'libass.so' 'libavcodec.so' 'libavformat.so' 'libavutil.so'
'libfreetype.so' 'libswresample.so' 'libswscale.so' 'libudev.so')
optdepends=('libretro-desmume: Nintendo DS core'
'libretro-gambatte: Nintendo Game Boy/Game Boy Color core'
'libretro-mgba: Nintendo Game Boy Advance core'
'libretro-mupen64plus: Nintendo 64 core'
'libretro-nestopia: Nintendo Entertainment System core'
'libretro-pcsx-rearmed: Sony PlayStation core'
'libretro-reicast: Sega Dreamcast core'
'libretro-yabause: Sega Saturn core'
'libretro-overlays: Collection of overlays'
'libretro-shaders: Collection of shaders'
'retroarch-assets-xmb: XMB menu assets'
'retroarch-autoconfig-udev: udev joypad autoconfig')
backup=('etc/retroarch.cfg')
source=("retroarch-${pkgver}.tar.gz::https://github.com/libretro/RetroArch/archive/v${pkgver}.tar.gz"
'libre.patch')
sha256sums=('a5733a0f4ad828afd00fa2a059deb6538939d46a2aefc4a566c30300a40efb1c'
'1df45fe1e42b2494c0906856d08648325c4e854252b87ad975e8fa33504b8949')
prepare() {
cd RetroArch-${pkgver}
patch -p1 -i ${srcdir}/libre.patch
}
build() {
cd RetroArch-${pkgver}
./configure \
--prefix='/usr' \
--disable-cg \
--disable-jack \
--disable-oss
make
make -C gfx/video_filters
make -C audio/audio_filters
}
package() {
cd RetroArch-${pkgver}
make DESTDIR="${pkgdir}" install
install -dm 755 "${pkgdir}"/usr/lib/retroarch/filters/{audio,video}
install -m 644 gfx/video_filters/*.{filt,so} "${pkgdir}"/usr/lib/retroarch/filters/video/
install -m 644 audio/audio_filters/*.{dsp,so} "${pkgdir}"/usr/lib/retroarch/filters/audio/
}
# vim: ts=2 sw=2 et:
|
