path: root/libre/texlive-bin/PKGBUILD

# $Id: PKGBUILD 281690 2016-11-21 06:27:04Z remy $
# Maintainer (Arch): Rémy Oudompheng <remy@archlinux.org>
# Contributor (Arch): francois <francois.archlinux.org>
# Maintainer: Michał Masłowski <mtjm@mtjm.eu>
# Contributor: André Silva <emulatorman@parabola.nu>
# Contributor: Isaac David <isacdaavid(at)isacdaavid!info>

pkgname=texlive-bin
pkgver=2016.41290
pkgrel=9.parabola1
license=('GPL')
arch=('i686' 'x86_64' 'armv7h')
makedepends=('cairo' 'pixman' 'graphite' 't1lib' 'gd' 'poppler=0.49.0'
         'libsigsegv' 'zziplib' 'libpng' 'libjpeg' 'freetype2'
         'icu=58.1' 'harfbuzz' 'harfbuzz-icu' 'gmp' 'mpfr' 'potrace' 'libpaper'
         'perl' 'clisp' 'ffcall')
url='http://tug.org/texlive/'
source=("https://sources.archlinux.org/other/texlive/texlive-bin-source-${pkgver}.tar.xz"
        "mktexlsr.hook"
        "mktexlsr.script"
        "texlive-updmap.hook"
        "texlive-updmap.script"
        "texlive-fmtutil.hook"
        "texlive-fmtutil.script")
md5sums=('7303361f2d441eb5c962a996fd77e8fa'
         'a4e54f0cb05f401728b2b230fd63b300'
         '2bbbef810687f4b2804a4b8cb91ce02f'
         '0ecdbd88cae12dbeb5d0d63127c5fc38'
         'c64d77b5111a26b9995263b49df4937c'
         '582af708588fd09eeaa0f08111e60091'
         '3f05fa08f84b94fcb3a76be271116a95')

build() {
   cd "$srcdir"

   if [ "${CARCH}" = "armv7h" ]; then
     local config_xindy="--disable-xindy"
   else
     local config_xindy="--enable-xindy"
   fi

   # t4ht expects to be un /usr/share/texmf/bin/t4ht (FS#27251)
   sed -i s/SELFAUTOPARENT/TEXMFROOT/ source/texk/tex4htk/t4ht.c
   #############################################################
   ### configure
   cd source
   ## prevent compiling Xdvi with libXp
   sed -i~ 's|-lXp ||' texk/xdvik/configure
   test ! -d Work && mkdir Work
   cd Work
   echo "--> Initial configuration..."
   # we use temporary prefix to avoid messing the existing
   # $pkgdir/usr/share/texmf tree
   ../configure --prefix=/usr -C \
     --sysconfdir=/etc \
     --datarootdir=/usr/share \
     --datadir=/usr/share \
     --mandir=/usr/share/man \
     --disable-native-texlive-build \
     --with-banner-add="/Parabola" \
     --disable-multiplatform \
     --disable-dialog \
     --disable-psutils \
     --disable-t1utils \
     --disable-bibtexu \
     --disable-xz \
     --enable-shared \
     --disable-static \
     --with-system-zlib \
     --with-system-zziplib \
     --with-system-pnglib \
     --with-system-ncurses \
     --with-system-t1lib \
     --with-system-gd \
     --with-system-poppler \
     --with-system-xpdf \
     --with-system-freetype2 \
     --with-system-pixman \
     --with-system-cairo \
     --with-system-harfbuzz \
     --with-system-graphite \
     --with-system-icu \
     --with-system-gmp \
     --with-system-mpfr \
     --with-system-potrace \
     --with-system-libpaper \
     --with-freetype2-libdir=/usr/lib \
     --with-freetype2-include=/usr/include/freetype2 \
     --with-xdvi-x-toolkit=xaw \
     --disable-dump-share \
     --disable-aleph \
     --enable-luatex \
     --with-clisp-runtime=default \
     --disable-xindy-rules --disable-xindy-docs "$config_xindy"
   #############################################################
   ### make
   echo "-------------------------------------------------------"
   echo "--> Building the whole beast ..."
   echo "-------------------------------------------------------"
   make
}

package() {
   pkgdesc="TeX Live binaries (Parabola rebranded)"
   depends=('cairo' 'pixman' 'graphite' 't1lib' 'gd' 'poppler=0.49.0'
            'libsigsegv' 'zziplib' 'libpng' 'libjpeg' 'freetype2'
            'icu=58.1' 'harfbuzz' 'harfbuzz-icu' 'gmp' 'mpfr' 'potrace' 'libpaper'
            'libsynctex')
   provides=('lcdf-typetools' 'kpathsea')
   provides_i686=('xindy')
   provides_x86_64=("${provides_i686[@]}")
   conflicts=('texlive-bin-libre' 'texlive-bin-parabola')
   replaces=('texlive-bin-libre' 'texlive-bin-parabola')
   optdepends=('ed: for texconfig'
               'biber: for bibliography processing')
   options=('!strip')

   cd "$srcdir"

   #############################################################
   ### install
   cd source
   # fixes for xindy
   find utils/xindy -name Makefile -exec sed -i -e "s|^prefix =.\+$|prefix = $pkgdir/usr|" -e "s|^mandir =.\+$|mandir = \${prefix}/share/man|" -e "s|^datadir =.\+$|datadir = \${datarootdir}/texmf|" -e "s|^docdir =.\+$|docdir = \${datadir}/doc/xindy|" '{}' \;

   echo "-------------------------------------------------------"
   echo "--> Proceeding with make install ..."
   echo "-------------------------------------------------------"
   cd Work
   make DESTDIR="${pkgdir}" texmf="$pkgdir"/usr/share/texmf install
   rm -rf "${pkgdir}"/usr/{texmf,share/texmf-dist}

   ## symlink engines by hand. texlinks has moved to texlive-core...
   mkdir -p ${pkgdir}/usr/bin
   ln -s eptex ${pkgdir}/usr/bin/platex
   ln -s euptex ${pkgdir}/usr/bin/uplatex
   ln -s luatex ${pkgdir}/usr/bin/dvilualatex
   ln -s luatex ${pkgdir}/usr/bin/dviluatex
   ln -s luatex ${pkgdir}/usr/bin/lualatex
   ln -s pdftex ${pkgdir}/usr/bin/amstex
   ln -s pdftex ${pkgdir}/usr/bin/cslatex
   ln -s pdftex ${pkgdir}/usr/bin/csplain
   ln -s pdftex ${pkgdir}/usr/bin/eplain
   ln -s pdftex ${pkgdir}/usr/bin/etex
   ln -s pdftex ${pkgdir}/usr/bin/jadetex
   ln -s pdftex ${pkgdir}/usr/bin/latex
   ln -s tex ${pkgdir}/usr/bin/lollipop
   ln -s pdftex ${pkgdir}/usr/bin/mex
   ln -s pdftex ${pkgdir}/usr/bin/mllatex
   ln -s pdftex ${pkgdir}/usr/bin/mltex
   ln -s pdftex ${pkgdir}/usr/bin/pdfetex
   ln -s pdftex ${pkgdir}/usr/bin/pdfcslatex
   ln -s pdftex ${pkgdir}/usr/bin/pdfcsplain
   ln -s pdftex ${pkgdir}/usr/bin/pdfjadetex
   ln -s pdftex ${pkgdir}/usr/bin/pdflatex
   ln -s pdftex ${pkgdir}/usr/bin/pdfmex
   ln -s pdftex ${pkgdir}/usr/bin/pdfxmltex
   ln -s pdftex ${pkgdir}/usr/bin/texsis
   ln -s pdftex ${pkgdir}/usr/bin/utf8mex
   ln -s pdftex ${pkgdir}/usr/bin/xmltex
   ln -s xetex ${pkgdir}/usr/bin/xelatex

   ## install pacman hooks
   install -D -m644 ${srcdir}/mktexlsr.hook "$pkgdir/usr/share/libalpm/hooks/mktexlsr.hook"
   install -D -m644 ${srcdir}/texlive-updmap.hook "$pkgdir/usr/share/libalpm/hooks/texlive-updmap.hook"
   install -D -m644 ${srcdir}/texlive-fmtutil.hook "$pkgdir/usr/share/libalpm/hooks/texlive-fmtutil.hook"
   install -D -m755 ${srcdir}/mktexlsr.script "$pkgdir/usr/share/libalpm/scripts/mktexlsr"
   install -D -m755 ${srcdir}/texlive-updmap.script "$pkgdir/usr/share/libalpm/scripts/texlive-updmap"
   install -D -m755 ${srcdir}/texlive-fmtutil.script "$pkgdir/usr/share/libalpm/scripts/texlive-fmtutil"

   #############################################################
   # remove dangling symlinks
   _bibtexextra_scripts="
bibexport
bibdoiadd
bibzbladd
listbib
ltx2crossrefxml
multibibliography
urlbst
"
   _core_scripts="
a2ping
a5toa4
adhocfilelist
afm2afm
allcm
allec
allneeded
arara
arlatex
autoinst
bundledoc
checkcites
checklistings
chkweb
cjk-gs-integrate
context
contextjit
ctanify
ctanupload
de-macro
depythontex
deweb
dosepsbin
dtxgen
dvi2fax
dviasm
dvired
e2pall
epstopdf
findhyph
fmtutil
fmtutil-sys
fontinst
fragmaster
installfont-tl
kpsepath
kpsetool
kpsewhere
kpsexpand
latex-git-log
latex2man
latexdiff
latexdiff-vc
latexfileversion
latexindent
latexmk
latexpand
latexrevise
listings-ext.sh
ltxfileinfo
ltximg
lua2dox_filter
luaotfload-tool
luatools
make4ht
match_parens
mf2pt1
mkjobtexmf
mkt1font
mktexfmt
mptopdf
mtxrun
mtxrunjit
ot2kpx
pdf180
pdf270
pdf90
pdfatfi
pdfbook
pdfbook2
pdfcrop
pdfflip
pdfjam
pdfjam-pocketmod
pdfjam-slides3up
pdfjam-slides6up
pdfjoin
pdfnup
pdfpun
pdfxup
pfarrei
pkfix
pkfix-helper
ps2eps
ps2frag
pslatex
purifyeps
pythontex
repstopdf
rpdfcrop
rungs
simpdftex
srcredact
sty2dtx
tex4ebook
texconfig
texconfig-dialog
texconfig-sys
texcount
texdef
texdiff
texdirflatten
texdoc
texdoctk
texexec
texfot
texindy
texlinks
texliveonfly
texloganalyser
texmfstart
thumbpdf
typeoutfileinfo
updmap
updmap-sys
vpl2ovp
vpl2vpl
xindy
"

   if [ "$CARCH" = "armv7h" ]; then
     _core_scripts="$(echo "$_core_scripts" | sed '/xindy$/d')"
   fi

   _games_scripts="rubikrotation"
   _htmlxml_scripts="ht htcontext htlatex htmex httex httexi htxelatex htxetex mk4ht"
   _humanities_scripts="diadia"
   _langcyrillic_scripts="rubibtex rumakeindex"
   _langextra_scripts="ebong"
   _langgreek_scripts="mkgrkindex"
   _langjapanese_scripts="convbkmk ptex2pdf
kanji-fontmap-creator
kanji-config-updmap
kanji-config-updmap-sys
"
   _langkorean_scripts="jamo-normalize komkindex ttf2kotexfont"
   _latexextra_scripts="
authorindex
exceltex
makedtx
makeglossaries
makeglossaries-lite
pdfannotextractor
perltex
ps4pdf
splitindex
svn-multi
vpe
yplan"
   _music_scripts="lily-glyph-commands lily-image-commands lily-rebuild-pdfs
m-tx musixtex musixflx pmx2pdf pmxchords"
   _pictures_scripts="
cachepic
epspdf
epspdftk
fig4latex
getmapdl
mathspic
mkpic
pn2pdf"
   _pstricks_scripts="pedigree pst2pdf"
   _science_scripts="pygmentex ulqda"
   for s in \
        ${_bibtexextra_scripts} \
        ${_core_scripts}        \
        ${_games_scripts}       \
        ${_htmlxml_scripts}     \
        ${_humanities_scripts}   \
        ${_langcyrillic_scripts} \
        ${_langextra_scripts}    \
        ${_langgreek_scripts}    \
        ${_langjapanese_scripts} \
        ${_langkorean_scripts} \
        ${_latexextra_scripts} \
        ${_music_scripts}      \
        ${_pictures_scripts}   \
        ${_pstricks_scripts}   \
        ${_science_scripts}    \
        tlmgr; do
       ! readlink -e "$pkgdir"/usr/bin/$s && rm "$pkgdir"/usr/bin/$s
   done
   ###################################################################

   # remove libsynctex
   rm -f "$pkgdir"/usr/include/synctex/*
   rm -f "$pkgdir"/usr/lib/libsynctex.*
   rm -f "$pkgdir"/usr/lib/pkgconfig/synctex.pc
   rm -f "$pkgdir"/usr/share/man/man*/synctex.*
}