blob: 9d296dd359ee420dfee7cdcb88f91d2258c353a0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Parabola maintainer: Michał Masłowski <mtjm@mtjm.eu>
# Maintainer: Rémy Oudompheng <remy.archlinux.org>
pkgname=texlive-fontsextra-libre
_pkgname=texlive-fontsextra
pkgver=2011.22691
_revnr=${pkgver#2011.}
pkgrel=1
pkgdesc="TeX Live - all sorts of extra fonts"
license=('GPL')
arch=(any)
depends=('texlive-core')
groups=('texlive-most')
replaces=('texlive-fontsextra')
conflicts=('texlive-fontsextra')
provides=('texlive-fontsextra')
url='http://tug.org/texlive/'
source=("http://repo.parabolagnulinux.org/other/${pkgname}-${pkgver}.tar.xz"
"${_pkgname}.maps")
options=('!emptydirs')
options=(!strip)
install=texlive.install
md5sums=('33f8fc7b7ff98c616a0a7a0b5844e603'
'5150fc36c158776c6317ac14bbd677ab')
mksource() {
[ -f ${_pkgname}-$pkgver-src.zip ] || wget ftp://ftp.archlinux.org/other/texlive/${_pkgname}-$pkgver-src.zip
mkdir ${pkgname}-${pkgver}
pushd ${pkgname}-${pkgver}
bsdtar xf ../${_pkgname}-$pkgver-src.zip
# remove nonfree packages
# No specific free license.
rm ogham.tar.xz
# Remove them from package list.
sed -ri '/^ogham /d' CONTENTS
popd
tar cJf ${pkgname}-${pkgver}.tar.xz ${pkgname}-${pkgver}
rm -rf ${pkgname}-${pkgver}
}
build() {
cd "$srcdir/${pkgname}-${pkgver}"
for p in *.tar.xz; do
bsdtar -xf $p
done
rm -rf {tlpkg,doc,source} || true
}
package() {
cd "$srcdir/${pkgname}-${pkgver}"
install -m755 -d $pkgdir/var/lib/texmf/arch/installedpkgs
sed -i '/^#/d' CONTENTS
install -m644 CONTENTS $pkgdir/var/lib/texmf/arch/installedpkgs/${_pkgname}_${_revnr}.pkgs
install -m644 $srcdir/${_pkgname}.maps $pkgdir/var/lib/texmf/arch/installedpkgs/
install -m755 -d $pkgdir/usr/share
wanteddirs=$(for d in *; do test -d $d && [[ $d != texmf* ]] && echo $d; done) || true
for dir in $wanteddirs; do
find $dir -type d -exec install -d -m755 $pkgdir/usr/share/texmf-dist/'{}' \;
find $dir -type f -exec install -m644 '{}' $pkgdir/usr/share/texmf-dist/'{}' \;
done
if [[ -d texmf-dist ]]; then
find texmf-dist -type d -exec install -d -m755 $pkgdir/usr/share/'{}' \;
find texmf-dist -type f -exec install -m644 '{}' $pkgdir/usr/share/'{}' \;
fi
if [[ -d $pkgdir/usr/share/texmf-dist/scripts ]]; then
find $pkgdir/usr/share/texmf-dist/scripts -type f -exec chmod a+x '{}' \;
fi
# remove stuff depending on omega/aleph
rm -rf $pkgdir/usr/share/texmf-dist/omega
find $pkgdir/ -wholename '*ocherokee*' -delete
find $pkgdir/ -wholename '*oinuit*' -delete
}
|
