blob: 1ee5bfff4d87d17aa3d1171b21178b2b5c101332 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id: PKGBUILD 149983 2015-12-07 15:41:10Z fyan $
# Maintainer (Arch): Peter Richard Lewis <plewis@aur.archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Emanuele Rossi <newdna1510@yahoo.it>
# Contributor (Arch): Bram Schoenmakers <me@bramschoenmakers.nl>
# Maintainer: Márcio Silva <coadde@parabola.nu>
pkgname=choqok
pkgver=1.5
pkgrel=4.nonprism1
pkgdesc="A Pump.io/GNU social client for KDE, without Twitter support"
url='http://choqok.gnufolks.org/'
license=('GPL')
arch=('i686' 'x86_64')
conflicts=(${pkgname}-nonprism)
replaces=(${pkgname}-nonprism)
depends=('kdebase-runtime' 'qjson' 'qoauth')
makedepends=('cmake' 'automoc4' 'telepathy-qt')
optdepends=('kdebase-konqueror: proxy support'
'telepathy-qt: IMstatus plugin')
install="${pkgname}.install"
source=("http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.xz")
md5sums=('f2efdd76199f8276e8ac2f76dc600596')
prepare() {
mkdir build
cd "${srcdir}/${pkgname}-${pkgver}"
# remove twitter service and keep only twitterapi (choqok software) for Pump.io, GNU social and libre collaboration services
sed -i '\|add_subdirectory(twitter)|d' microblogs/CMakeLists.txt
sed -i 's|twitter[.]com|status.net|' microblogs/laconica/laconicamicroblog.cpp
sed -i 's|twitter[.]com|status.net|' microblogs/laconica/laconicasearch.cpp
# remove uploaders plugin (with nonprivacy services only)
sed -i '\|add_subdirectory(uploaders)|d' plugins/CMakeLists.txt
sed -i 's|Comment||' plugins/searchaction/choqok_searchaction.desktop
# remove twitter on docbook
sed -i 's| and Twitter.com||
s| and another with the alias|.</para>|
s|while a post using Twitter is called a tweet||
\|Twitter|d;\|twitter|d' doc/index.docbook
}
build() {
cd build
cmake ../${pkgname}-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr
make
}
package() {
cd build
make DESTDIR="${pkgdir}" install
}
|
