blob: b444b6ec875d936071e2853b3d0a7d0625d7f1af (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Luke R. <g4jc@openmailbox.org> GPG: rsa4096/3EAE8697
# (Arch) Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=webkit2gtk
pkgver=2.10.4
pkgrel=3.nonprism1
pkgdesc="GTK+ Web content engine library, without geoclue2/geolocation tracking support"
arch=('i686' 'x86_64')
url="http://webkitgtk.org/"
license=('custom')
depends=('libxt' 'libxslt' 'enchant' 'gst-plugins-base-libs'
'libsecret' 'libwebp' 'harfbuzz-icu' 'gtk3' 'libnotify' 'hyphen')
makedepends=('gtk2' 'gperf' 'gobject-introspection' 'ruby' 'gtk-doc' 'cmake' 'python')
optdepends=('gtk2: Netscape plugin support'
'gst-plugins-base: free media decoding'
'gst-plugins-good: media decoding'
'gst-libav: nonfree media decoding')
options=('!emptydirs')
source=(http://webkitgtk.org/releases/webkitgtk-${pkgver}.tar.xz)
sha512sums=('1d1c79fb863be192639304c5616fb875ccfe541617fdc5c973e79d8159131080ba734199959a01760b9d06accaae7e2e87bec3bcc42dcd2e6b0d19a5b82ed039')
prepare() {
mkdir build
cd webkitgtk-$pkgver
sed -i '1s/python$/&2/' Tools/gtk/generate-gtkdoc
rm -r Source/ThirdParty/gtest/
rm -r Source/ThirdParty/qunit/
##Disable GeoClue location tracking##
sed -i '/geoclue/d' Source/WebCore/PlatformGTK.cmake
sed -i '/geoclue/d' Tools/gtk/install-dependencies
rm -r Source/WebCore/platform/geoclue/
rm Source/cmake/FindGeoClue.cmake
rm Source/cmake/FindGeoClue2.cmake
sed -i 's/WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_GEOLOCATION PUBLIC ON)/WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_GEOLOCATION PUBLIC OFF)/' Source/cmake/OptionsGTK.cmake
##
}
build() {
cd build
cmake -DPORT=GTK -DCMAKE_BUILD_TYPE=Release \
-DCMAKE_SKIP_RPATH=ON -DCMAKE_INSTALL_PREFIX=/usr \
-DLIB_INSTALL_DIR=/usr/lib -DLIBEXEC_INSTALL_DIR=/usr/lib/webkit2gtk-4.0 \
-DENABLE_GTKDOC=ON ../webkitgtk-$pkgver
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
install -m755 -d "$pkgdir/usr/share/licenses/webkit2gtk"
cd "$srcdir/webkitgtk-$pkgver/Source"
for f in $(find -name 'COPYING*' -or -name 'LICENSE*'); do
echo $f >> "$pkgdir/usr/share/licenses/webkit2gtk/LICENSE"
cat $f >> "$pkgdir/usr/share/licenses/webkit2gtk/LICENSE"
echo "" >> "$pkgdir/usr/share/licenses/webkit2gtk/LICENSE"
done
}
|
