blob: 3db26a3906fd4862e3bbc6967066b6e293262ab8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer (Arch): Andrejs Mivreņiks <gim at fastmail dot fm>
# Contributor (Arch): Janne Haapsaari <haaja@iki.fi>
# Maintainer: André Silva <emulatorman@parabola.nu>
pkgname=gnome-shell-pomodoro
pkgver=0.11.1
pkgrel=1.parabola1
pkgdesc='A time management utility for GNOME based on the pomodoro technique, without nonfree Skype support'
arch=('i686' 'x86_64')
url='https://github.com/codito/gnome-shell-pomodoro/'
license=('GPL3')
depends=('gnome-desktop' 'libcanberra' 'upower' 'gstreamer' 'gobject-introspection' 'perl-xml-sax-expat' 'telepathy-glib')
makedepends=('intltool' 'vala' 'gnome-common' 'docbook2x')
conflicts=('gnome-shell-pomodoro-git')
install='gschemas.install'
source=("$pkgname-$pkgver.tar.gz::https://github.com/codito/gnome-pomodoro/archive/$pkgver.tar.gz"
'libre.patch')
sha256sums=('90217c2df07ef7da2f1e8fba4e657a18954d03bc09fe93ba4405aa6e12df1a7a'
'acb05ba020439a6ae20a87b9f40b51a2b0aff836180349e7750e647e479148dc')
prepare() {
cd "$srcdir/gnome-pomodoro-$pkgver"
# Remove Skype stuff
rm -rv lib/skype{,-plugin}.vala
patch -Np1 -i ../libre.patch
# Fixes some build issues when 'docbook2x' package is installed
# Big thanks to user maus25 for the fix
sed -i "s/docbook2man \$?/docbook2man --sgml \$?/g" man/Makefile.am
./autogen.sh --prefix=/usr --datadir=/usr/share
}
build() {
cd "$srcdir/gnome-pomodoro-$pkgver"
make
}
package() {
cd "$srcdir/gnome-pomodoro-$pkgver"
make DESTDIR="$pkgdir" install
}
|
