pcr/perl-regexp-common/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer (Arch): Jason St. John <jstjohn .. purdue . edu>
# Contributor (Arch): Caleb Cushing <xenoterracide@gmail.com>
# Contributor: Márcio Silva <coadde@parabola.nu>

_perlmod=Regexp-Common
_modnamespace=Regexp
pkgname=perl-regexp-common
pkgver=2015121601
pkgrel=1
pkgdesc="Regexp::Common - Provides commonly requested regular expressions"
arch=('any')
url="http://search.cpan.org/dist/${_perlmod}"
license=('MIT')
options=('!emptydirs')
source=("http://cpan.org/modules/by-module/${_modnamespace}/${_perlmod}-${pkgver}.tar.gz")
sha512sums=('3e733327b2a3c00d2eb13aaa36914dea981eff1220fd24017f1edfeff18daceb5c008a9c2cf11fcb12c495a36eb3ab60bee44904210ecb46ef70d14809fd021e')

build() {
	cd "${_perlmod}-${pkgver}"

	# Install module in vendor directories.
	PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
	make
}

check() {
	cd "${_perlmod}-${pkgver}"
	make test
}

package() {
	cd "${_perlmod}-${pkgver}"
	make install DESTDIR="${pkgdir}"
}