blob: b20b1c2487d419b2e31d6ac16215d424090cf3c7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# $Id: PKGBUILD 112179 2014-05-29 15:06:03Z arcanis $
# Maintainer: Evgeniy Alekseev <arcanis.arch at gmail dot com>
# Contributor: Stunts <f.pinamartins at gmail dot com>
# Contributor: damir <damir at archlinux dot org>
pkgbase=python-biopython
pkgname=('python-biopython' 'python2-biopython')
_pkgname=biopython
pkgver=1.64
pkgrel=1
pkgdesc="Freely available Python tools for computational molecular biology"
arch=('i686' 'x86_64')
url="http://www.biopython.org"
license=('custom')
depends=('python-numpy' 'python2-numpy')
source=(http://www.biopython.org/DIST/${_pkgname}-${pkgver}.tar.gz)
md5sums=('c7636372c4e775d59391e0aa1f0c56c7')
prepare() {
cp -r "${_pkgname}-${pkgver}" "${_pkgname}-${pkgver}-py2"
# change python to python2
find "${_pkgname}-${pkgver}-py2" -name '*.py' -type f -exec \
sed -i 's|env python|env python2|' {} \;
}
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
python setup.py build
cd "${srcdir}/${_pkgname}-${pkgver}-py2"
python2 setup.py build
}
package_python-biopython() {
depends=('python-numpy')
cd "${srcdir}/${_pkgname}-${pkgver}"
python setup.py install --root="${pkgdir}"
install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
package_python2-biopython() {
depends=('python2-numpy')
optdepends=('python2-reportlab: for pdf graphics code'
'mysql-python: for BioSQL module')
cd "${srcdir}/${_pkgname}-${pkgver}-py2"
python2 setup.py install --root="${pkgdir}"
install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
